• Главная
• В избранное
• Наш E-MAIL
• Добавить материал
• Нашёл ошибку
• Вниз

Цепи постоянного тока важны не только сами по себе, но и потому, что многие приемы, применяемые при их анализе, используются и при анализе цепей переменного тока. В действительности анализ большинства электронных цепей и приборов может быть проведен одними и теми же методами.

Наиболее важным свойством последовательной цепи из трех резисторов, подсоединенных к источнику постоянного напряжения (рис. 1.1), является то, что через все ее элементы течет один и тот же ток.

Рис. 1.1. Последовательная цепь с тремя резисторами

Другое важное ее свойство заключается в том, что приложенное напряжение (50 В) делится между резисторами прямо пропорционально их сопротивлению. Например, падение напряжения на резисторе в 150 Ом втрое больше падения напряжения на резисторе сопротивлением 50 Ом. Применяя концепцию деления напряжения, легко найти падение напряжения на каждом элементе, даже не зная тока в цепи. Так, напряжение на R₃ равно:

а падение напряжения на R₂:

Ток также просто находится с помощью любого из следующих уравнений:

Вход в PSpice начинается с команд File, New, Text File. Анализ схемы можно провести с помощью представленного ниже входного файла:

Spice Analysis of Series Circuit

Vs 1 0 50V

R1 1 2 100 

R2 2 3 50

R3 3 0 150

.OP

.END

Напомним, что после того как набрана последняя команда (.END), Enter лучше не нажимать. После ввода всех строк файла используйте набор команд File, Save и введите имя файла, например Probe1.cir. Как было отмечено ранее, лучше всего хранить все входные файлы в папке SPICE, используя правильный путь к папке, который будет выглядеть, например, c:/SPICE. Окно Save as type должно показывать «Circuit Files (*.cir)».

Закройте файл, используя команды File, Close и снова откройте его с помощью команд File, Open. Теперь Вы готовы к проведению моделирования с помощью команд Simulation, Run prob1. Перед тем как это сделать, вы можете использовать команду View и проверить «Output Window» и «Simulation Status Window». После завершения моделирования экран должен выглядеть так, как показано на рис 1.2. Отметим, что на дисплей должно быть выведено в нижнем левом окне окончательное состояние и сообщение об окончании моделирования: «Simulation complete».

Рис. 1.2. Экран PSpice после завершения моделирования 

Вы можете увидеть результаты моделирования с помощью команд View, Output File. При этом экран покажет не только результаты моделирования, но и отметит некорректные команды во входном файле при их наличии. Мы рекомендуем вам не распечатывать выходной файл в той форме, в какой он представлен в PSpice, поскольку он содержит лишние пустые строки. Вместо этого, используя команды File и Close, закройте выходной файл, сверните окно PSpice и воспользуйтесь такими редакторами, как Microsoft Word или WordPad. Если, пользуясь этими редакторами, вы устраните пустые строки и ненужные разрывы страниц, возможно, результат можно будет распечатать на одной странице.

Наиболее важные части выходного файла содержат информацию о напряжениях различных узлов:

Node Voltage Node Voltage Node Voltage

(1)  50.0000 (2)  33.3330 (3)  25.0000

Потенциал узла 1 — это напряжение V₁₀, напряжение источника питания. Потенциал узла 2 — напряжение V₂₀, суммарное падение напряжения на R₂ и R₃. Напряжение узла 3 — напряжение V₃₀ является падением напряжения на резисторе R₃.

Как мы рассчитали ранее, напряжение V_R3 (равное V30) составляет 25 В, следовательно, анализ на PSpice оказался верным. Как можно теперь определить напряжение на R₂? Оно равно V₂–V₃, и его можно вычислить как V₂₀–V₃₀.

V₂ – V₃ = 33,333 – 25,000 = 8,333 В.

Анализ на PSpice учитывает также напряжение и ток источника питания; напряжение на источнике питания V задано в исходных данных, ток через него, согласно выходному файлу, равен -1.667Е-01. Ток имеет правильное числовое значение, но почему его знак отрицателен? SPICE показывает ток, который течет от плюса к минусу внутри источника питания, а поскольку реально ток внутри источника питания течет от минуса к плюсу, то знак тока отрицателен. Проще говоря, когда ток отрицателен, он течет от плюса к минусу во внешней цепи источника питания.

Отметим, что полная рассеиваемая мощность также определяется при моделировании на PSpice и составляет 8,33 Вт. Это просто произведение тока I на напряжение V: 50×0,1667=8,33 Вт. Для схемы (рис. 1.1), которая содержит всего одну ветвь, мы получили практически исчерпывающую информацию. Для получения других величин рассмотрим следующую, несколько более сложную, схему. 

Рассмотрим теперь Т-образную схему с источником постоянного напряжения в 50 В и нагрузочным резистором R4=150 Ом (рис. 1.3). Сопротивление нагрузочного резистора может изменяться в произвольных пределах. Можно представить себе нагрузочный резистор как выходной (то есть подключенный на выход схемы).

Рис. 1.3. Т-образная схема

Как можно найти напряжение и ток на этом резисторе или, согласно обозначениям на рис. 1.3, напряжение V₃ и ток I (ток, подходящий от узла 3 к узлу 0)?

Входное сопротивление схемы находится путем сложения R₂ и R₄ (получим 200 Ом), включения этой цепочки параллельно R₃ (200||200=100 Ом) и добавления R₁ (сумма будет равна 200 Ом). Таким образом, R_BX=200 Ом. Ток источника (входной ток) равен V/R_BX=50/200=0,25 А (ток направлен от плюсового полюса источника V).

Падение напряжения на R₁ равно IR₁=0,25·100=25 В на R₃ равно V–V_R1=50–25=25 В.

Падение напряжения на R₄ определим из выражения для делителя напряжения:

Ток I находится как V_R4/R₄=18,75/150=0,125 А.

На рис. 1.3 напряжение на R₄ обозначим как V₃, точнее было бы обозначить это напряжение как V₃₀. Можно выполнить анализ и другими методами, что мы и советуем вам проделать.

После того как у вас будут результаты ручного расчета, рассмотрим, как это делается на PSpice. Создайте файл с именем probe 2.cir со следующими командами:

Spice Analysis of a Tee Circuit

Vs 1 0 50V

R1 1 2 100

R2 2 3 50

R3 2 0 200

R4 3 0 150

.OP

.OPTION NOPAGE

.TF V(3) V

.END

Как обычно, такой файл начинается с заголовка и оканчивается командой .END. В этом файле появилась новая команда: .TF. Она выводит в выходном файле передаточную функцию (transfer function), которая представляет собой отношение выходного напряжения ко входному. В нашем случае выходное напряжение V(3) представляет собой падение напряжения на R₄, а входное напряжение есть просто напряжение V источника питания. Вы сами выбираете, какое из напряжений сделать выходным, это может быть напряжение и на каком-либо другом резисторе. Для того чтобы определить передаточную функцию, можно просто взять отношение V(3)/V. В нашем случае оно равно 18,75/50 = 0,375.

Команда .OPTION с опцией NOPAGE предотвращает вывод ненужных заголовков и колонтитулов. В нашем примере применение этой команды не приводит к существенному изменению выходного файла, и в ней нет особой необходимости. Но лучше автоматически включать эту команду во все входные файлы. Она освободит вас от необходимости ручного исключения некоторых лишних строк при редактировании выходного файла.

Запустите моделирование на PSpice с помощью команды RUN и выберите prob2.out. Вспомните, что необходимо избавиться от лишних строк в выходном файле, и распечатайте его копию для дальнейшего изучения. Проверим падение напряжения на R₃. Оно обозначено как V(2) в выходном файле. Проверим также падение напряжения на R₄, которое обозначено как V(3) на рис. 1.3. Ток источника питания представлен как -2,5Е-1 или -0,25 А. Совпадает это значение с полученным нами при предварительном расчете? Теперь можно посмотреть и дополнительную информацию, полученную с помощью команды .TF. Эта строка всегда содержит имя источника питания. Проверим наши вычисления R_BX=200 Ом. То же значение получено и при помощи PSpice.

А чему равно выходное сопротивление? Так как в качестве выходного напряжения в строке .TF введено V(3), то выходное сопротивление представляет собой сопротивление цепи между узлами 3 и 0 при закороченном источнике питания V (именно закороченном, а не просто исключенном). В схеме для вычисления выходного сопротивления резисторы R₁ и R₃ соединены параллельно, эта цепочка соединена последовательно с R₂, а вся полученная комбинация резисторов подсоединена параллельно R₄. Проверьте, что сопротивление такого соединения составляет R_вых=65,63 Ом. Во многих случаях желательно сравнить выходное напряжение с входным. Иногда отношение этих напряжений называют коэффициентом усиления по напряжению. В цепях, содержащих один источник питания и пассивные компоненты (например резисторы, как на рис. 1.3), коэффициент усиления не может превышать 1. В нашем случае он составляет 0,375.

Таким образом, мы сравнили результаты расчета и анализа на PSpice простой резистивной цепи. Необходимо отметить, что мы не ставили цели использовать инструмент PSpice для понимания теории цепей. Если вы не знаете, как вычислить общее сопротивление цепи, составленной из резисторов при последовательном и параллельном соединении, то компьютерный анализ вряд ли сможет обучить вас этому. На самом деле, напротив, вы скорее обнаружите, что разобраться в результатах анализа на PSpice легче, имея опыт ручного расчета схем.

Вы, конечно, можете спросить: «А для чего же нам тогда PSpice?» Есть две причины, по которым эта программа может вам пригодиться. Поняв на простых схемах, как работает PSpice, вы сможете применить этот инструмент к значительно более сложным цепям, которые рассчитать вручную далеко не просто. И кроме того, вы сможете разобраться в различных расчетах на PSpice, широко применяемых в настоящее время в профессиональной деятельности.

Запомним, что строка, представляющая источник питания, начинается с V, а строка, представляющая резистор, — с R. Удобно применять обозначения, отражающие структуру исследуемой цепи, например, VS или VIN для источника питания и RS для его внутреннего сопротивления.

Рассмотрим наиболее распространенные методы анализа цепей и применение PSpice для проверки важнейших теорем электротехники.

При изучении электрических цепей широко применяется второй закон Кирхгофа, согласно которому алгебраическая сумма напряжений на замкнутом контуре равна 0. Первый закон Кирхгофа относится к токам, подходящим к узлу, и утверждает, что алгебраическая сумма таких токов также равна 0. Анализ схемы на рис. 1.4 может продемонстрировать нам выполнение этих двух законов. Эта цепь содержит три контура и четыре узла (в дополнение к опорному узлу 0). Мы не будем сейчас рассчитывать ее вручную, а сразу применим PSpice. Сделайте это самостоятельно с помощью приведенного далее входного файла, а затем проверьте результат:

Bridge Circuit for Use with Basic Circuit Laws

V 3 0 25V

R1 1 2 100

R2 1 0 75

R3 2 3 50

R4 4 0 50

R5 2 4 150

R6 1 4 200

.OP

.END

Рис. 1.4. Цепь с тремя контурами

Запустите моделирование на PSpice и получите копию распечатки для дальнейших исследований.

Мы рекомендуем оставить пустое пространство на распечатке, чтобы нарисовать эскиз схемы, обозначив на ней все получаемые величины. Покажите расположение всех узлов, которые используются в командах. Вам легче будет различать отдельные узлы, если вы обозначите их разным цветом.

Найдите сумму напряжений в левом контуре, а именно:

V₁₂ + V₂₃ + V₃₀ + V₀₁.

Вспомним, что V₁₂ это (на самом деле V₁–V₂) и так далее. Проверим значения при соответствующих номерах узлов:

-9,7039 - 8,632 + 25,000 - 6,6641 = 0.

Нулевая сумма подтверждает закон Кирхгофа. Напишите теперь равенства для правого контура в символическом виде и проверьте равенство суммы нулю, подставив необходимые значения

V₁₃ + V₃₄ + V₄₁ = 0.

В соответствии с рис.1.4 V₁₃ может быть найдено как (V₁–V₃). Вы можете пройти подобным образом весь путь от узла 1 к узлу 2, и затем от узла 2 к узлу 3. Если вы будете измерять напряжение V₁₃ в лаборатории, то вам придется подсоединить красный провод тестера к узлу 1, а черный провод — к узлу 3. Вольтметр должен показать –18,34 В. Проверьте ваши вычисления суммы напряжений:

-18,3359 + 19,9727 - 1,6368 = 0.

Вспомним порядок описания при положительном и отрицательном напряжениях. При этом, если величина V₁₂ положительна (скажем, 6,5 В), то величина V₂₁ должна быть отрицательной (-6,5 В). Важность придания величине определенного знака невозможно переоценить. Например, если все слагаемые в уравнениях для первого или второго законов Кирхгофа будут с одним знаком, эти законы не будут выполняться.

Найдем теперь сумму токов, подходящих к узлу 1. Обозначим их I₂₁, I₀₁ и I₄₁. Покажем ее в символической форме, а затем вычислим значения:

Сумма токов равна 0, что подтверждает первый закон Кирхгофа. Значение тока I₀₁ округлено до пяти значащих цифр. Сумма, конечно, может несколько отличаться от 0 из-за округления. В обозначениях токов чаще применяется один нижний индекс, чем два. При использовании одного индекса мы должны указать направление тока на схеме, в противном случае появляется неоднозначность (!). Это так же важно, как и указание знака при напряжениях.

Приведенный входной файл не позволяет нам получить из выходного файла исчерпывающую информацию. Неясно, например, каковы будут токи в отдельных ветвях. Изменим входной файл, включив в него дополнительно следующие команды:

.PRINT DC I(R1) I(R2) I(R3)

.PRINT DC I(R4) I(R5) I(R6)

.DC V 25V 25V 25V

.OPT nopage

Запись .OPT nopage является сокращенной записью команды .OPTion nopage. Сохраните новую версию входного файла и снова запустите моделирование. Результат приведен на рис. 1.5. Команда .PRINT использована, чтобы получить в выходном файле токи через различные резисторы.

**** 07/26/05 15:25:43 *********** Evaluation Pspice (Nov 1999) **************

Bridge Circuit for Use with Basic Circuit Laws

**** CIRCUIT DESCRIPTION

V 3 0 25V

R1 1 2 100

R2 1 0 75

R3 2 3 50

R4 4 0 60

R5 2 4 150

R6 1 4 200

.PRINT DC I(R1) I(R2) I(R3)

.PRINT DC I(R4) I(R5) I(R6)

.DC V 25V 25V 25V

.OPT nopage

.END

**** DC TRANSFER CURVES TEMPERATURE = 27.000 DEG С

V         I(R1)      I(R2)     I(R3)

2.500E+01 -9.704E-02 8.885E-02 -1.726E-01

**** DC TRANSFER CURVES TEMPERATURE = 27.000 DEG С

V         I(R4)     I(R5)     I(R6)

2.500E+01 8.379E-02 7.560E-02 8.184E-03

**** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG С

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 6.6641  ( 2) 16.3680 ( 3) 25.0000 ( 4) 5.0273

VOLTAGE SOURCE CURRENTS

NAME CURRENT

V    -1.726E-01

TOTAL POWER DISSIPATION 4.32E+00 WATTS

**** OPERATING POINT INFORMATION TEMPERATURE = 27.000 DEG С

JOB CONCLUDED

TOTAL JOB TIME .07

Рис. 1.5. Выходной файл при моделировании схемы на рис. 1.4

Некоторые токи в распечатке приведены как положительные, другие — как отрицательные. Например, запись I(R1)=-9,704Е-02 означает ток I_R1=-97,04 мА. Описание резистора R₁ во входном файле имеет вид:

R1 1 2 100

Поскольку PSpice дает для тока I(R1) отрицательный знак, реальное направление тока в схеме — от узла 2 к узлу 1 (условное направление принято обратным). Чтобы опять проверить первый закон Кирхгофа, подсчитаем сумму токов, подходящих к узлу 2. Запишем равенство в символьной форме, затем подставим значения.

На рис. 1.6 показана схема с двумя источниками напряжения. Хотя схема не слишком сложна, для нахождения токов и напряжений в ней требуется немало усилий. Мы предполагаем, что вы не будете применять метод контурных токов или узловых потенциалов, хотя в дальнейшем мы будем использовать и эти методы. Применим другую, во многом интуитивную методику, в которой определяются воздействия от каждого источника питания порознь[4]. Для этого нужно рассчитать цепь а с источником V₁ при неактивном (закороченном) источнике V₂, а затем цепь b с активным источником V₂ при неактивном источнике V₁.

Рис. 1.6. Схема с двумя источниками напряжения 

Нарисуйте исходную схему, а также схемы а и b. Найдите напряжения узла 2 в каждой из схем а и b. После этого проверьте полученные результаты, должно получиться V₂(a)=6,75 В, V₂(b)=5,06 В. Согласно принципу наложения (суперпозиции) действительное напряжение на узле 2 равно сумме этих двух значений, то есть 11,81 В.

Можно найти ток источника V₁ из выражения:

Принцип суперпозиции применяется в цепях, содержащих линейные резисторы и более одного источника питания, однако при трех и более источниках вычисления могут оказаться долгими и утомительными.

Вот здесь Spice и оказывается очень полезным, существенно облегчая вашу работу. Входной файл выглядит следующим образом:

Circuit with Two Voltage Circuit

V1 1 0 20V

V2 3 0 12V

R1 1 2 100

R2 2 3 80

R3 2 0 140

.OP

.OPT nopage .TF V(2) V1 .END

Результат на PSpice дает V(2)=11,807 В, в точном соответствии с расчетом методом наложения. Ток источника V₁ дает в PSpice значение -8.193Е-2. Минус означает, что ток во внешней цепи идет от положительного полюса источника V₁. Что означает приведенное в выходном файле входное сопротивление? Это сопротивление, которое «видит» источник V₁ при замкнутом источнике V₂. Оно образуется резистором в 80 Ом, подключенным параллельно резистору в 140 Ом, и подключением этой цепочки последовательно с резистором в 100 Ом, что дает входное сопротивление R_BX=150,9 Ом.

А можете ли вы объяснить, что такое выходное сопротивление? Вспомним, что согласно команде .TF выходной переменной считается V(2).

Нарисуйте схему выходного сопротивления относительно узлов 2 и 0 при закороченных источниках питания. При этом получится цепочка из резисторов R₁, R₂, R₃, включенных параллельно. Легко проверить, что сопротивление такой цепочки составляет 33,7 Ом, (что соответствует результатам на рис. 1.7).

**** 07/26/05 15:40:49 *********** Evaluation PSpice (Nov 1999) *************

Circuit with Two Voltage Circuit

**** CIRCUIT DESCRIPTION

V1 1 0 20V

V2 3 0 12V

R1 1 2 100

R2 2 3 80

R3 2 0 140

.OP

.OPT nopage

.TF V(2) V1

.END

**** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG С

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 20.0000 ( 2) 11.8070 ( 3) 12.0000

VOLTAGE SOURCE CURRENTS

NAME CURRENT

V1  -8.193E-02

V2  -2.410E-03

TOTAL POWER DISSIPATION 1.67E+00 WATTS

**** OPERATING POINT INFORMATION TEMPERATURE = 27.000 DEG С

**** SMALL-SIGNAL CHARACTERISTICS

V(2)/V1 = 3.374E-01

INPUT RESISTANCE AT V1 = 1.509E+02

OUTPUT RESISTANCE AT V(2) = 3.374E+01

Рис. 1.7. Выходной файл при моделировании схемы на рис. 1.6 

Что представляет собой теорема Тевенина, и почему она так важна и так широко применяется? Если вы рассчитываете нетривиальные цепи и при этом хотите получить результат при различных нагрузочных сопротивлениях, то идеальным методом расчета и является применение теоремы Тевенина.

Схема на рис. 1.8(a) содержит источник напряжения и несколько резисторов, включая нагрузочный резистор R_L. Найдем напряжение на резисторе R_L и ток через него. Для этого можно найти эквивалентное сопротивление цепи, затем ток источника, падение напряжения на R₁ и так далее вплоть до падения напряжения на R_L. Однако если изменить сопротивление R_L, всю последовательность вычислений придется повторить. С помощью теоремы Тевенина эта проблема решается проще.

Рис. 1.8. К применению теоремы Тевенина: а — схема; б — источник эквивалентного напряжения и эквивалентное внутреннее сопротивление

Для начала удалим из схемы нагрузочное сопротивление. Этот метод не зависит от нагрузочного сопротивления, и это очень важно. Теперь найдем напряжение V₃₀, проще говоря, напряжение между узлами, к которым было подключено исключенное из схемы сопротивление нагрузки. Можно обозначить его как V_Th (Th — первые буквы имени Тевенина). Затем вычислим сопротивление схемы относительно этих же узлов, закоротив источник питания. Его можно обозначить как R_Th.

Заменим теперь схему неидеальным источником напряжения, содержащим идеальный источник V_Th с внутренним сопротивлением R_Th и вернем в полученную схему нагрузочное сопротивление R_L. Падение напряжения на этом резисторе и ток через него будут такими же, как в исходной схеме.

Найдем V_Th и R_Th для схемы рис. 1.8. Удалим R_L, затем используем выражение для делителя напряжения, чтобы вычислить V₂₀=50 В. Для определения R_Th закоротим источник V. Вычисляя теперь сопротивление относительно узлов 3 и 0, получим R_Th=216,67 Ом. Неидеальный источник напряжения состоит из включенных последовательно V_Th и R_Th, рис. 1.8(б). Для новой схемы гораздо проще получить значения тока и напряжения на нагрузке при любом значении R_L. Например, при R_L=200 Ом найдем, применяя выражение для делителя напряжения, V₃₀=24 В, а при R_L=300 Ом получим V₃₀=29 В.

Продолжим исследование схемы на рис. 1.8, применяя теперь для проверки полученного нами решения PSpice. Вместо того чтобы удалять сопротивление R_L, изменим реальное значение сопротивления R_L на очень большое, например в 1 ТОм (1Е12). Входной файл будет иметь вид:

Thevenin Circuit for Spice

V 1 0 75V

R1 1 2 100

R2 2 3 150

R3 2 0 200

RL 3 0 1E12

.OP

.OPT nopage

.TF V(3) V

.END

После запуска PSpice, заметим, что V(2) = 50,0000 В и V(3) = 50,0000 В. Можете вы это объяснить, прежде чем продолжите разбор? Каково же значение V_Th?

Команда .TF дает значение выходного сопротивления относительно V(3), равное 216,7 Ом. Это и есть значение R_Th. Отметим, что значение R_L на несколько порядков превосходит любое другое сопротивление в схеме и практически не нагружает ее (опыт холостого хода). Попробуйте повторить анализ при существенно меньшем значении R_L. 

Предыдущий пример был относительно легким для расчета и без применения PSpice. Если мы сталкиваемся с более сложной задачей, например, с показанной на рис. 1.9, PSpice может сэкономить нам массу времени. Создайте самостоятельно входной файл для этой схемы и затем проверьте полученные вами результаты, исследуя приведенный ниже файл:

Thevenin Analysis of Bridged-Tee Circuit

V 1 0 75V

R1 2 1 20

R2 2 3 100

R3 3 0 200

R4 3 4 100

R5 2 4 400

R6 4 0 1E8

.OP

.OPT nopage

.TF V(4) V

.END

Рис. 1.9. Мостовая Т-образная схема 

Выходной файл показан на рис. 1.10. Напряжение V(4)=57,143 В и представляет собой V_Th. Выходное сопротивление относительно V(4) равно R_Th=128,6 Ом. Отметим, что как напряжение холостого хода, так и сопротивление цепи относительно выходных полюсов находятся при удаленном нагрузочном сопротивлении или при значении этого сопротивления столь высоком, что остальные сопротивления схемы становятся пренебрежимо малыми. 

**** 07/27/05 09:41:47 *********** Evaluation PSpice (Nov 1999) **************

Thevenin Analysis of Bridged-Tee Circuit

**** CIRCUIT DESCRIPTION

V 1 0 75V

R1 2 1 20

R2 2 3 100

R3 3 0 200

R4 3 4 100

R5 2 4 400

R6 4 0 1E8

.OP

.OPT nopage

.TF V(4) V

.END

**** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG С

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 75.0000 ( 2) 70.0550 ( 3) 49.4510 ( 4) 53.5710

VOLTAGE SOURCE CURRENTS

NAME CURRENT

V   -2.473E-01

TOTAL POWER DISSIPATION 1.85E+01 WATTS

**** OPERATING POINT INFORMATION TEMPERATURE = 27.000 DEG С

**** SMALL-SIGNAL CHARACTERISTICS

V(4)/V = 7.143E-01

INPUT RESISTANCE AT V = 3.033E+02

OUTPUT RESISTANCE AT V(4) = 1.286E+02

JOB CONCLUDED

TOTAL JOB TIME .05

Рис. 1.10. Выходной файл при моделировании схемы на рис. 1.9

По результатам анализа нарисуем эквивалентную схему для неидеального источника Тевенина, содержащую последовательно соединенные V_Th и R_Th. Ручной расчет вы можете провести самостоятельно.

Как вы думаете, просто исключив резистор R₆, решите ли вы тем самым задачу? Попытайтесь это сделать и посмотреть, изменится ли результат. Причина, по которой можно удалить R₆, состоит в том, что и в этом случае остается путь возврата от узла 4 на землю.

Схема на рис. 1.11 показывает другие возможности применения теоремы Тевенина. В этой схеме величине R_L присваивается ряд различных значений и предлагается вычислить ток и напряжение нагрузки для каждого из них. Мы убедились, что нагрузочное сопротивление может быть удалено из схемы вместо замены его резистором с очень большим сопротивлением.

Рис. 1.11. Схема для замещения по теореме Тевенина 

Это можно еще раз проверить с помощью следующего входного файла:

Bridge-Circuit for Thevenin

V 4 3 40V

R1 1 2 100

R2 2 0 150

R3 1 4 200

R4 4 0 200

R5 2 3 50

.OP

.OPT nopage

.TF V(1) V

.END

Запустите анализ и нарисуйте по его результатам неидеальный источник напряжения Тевенина. Убедитесь, что вы обозначили все необходимые узлы. Результат должен соответствовать рис. 1.12. Выходные узлы обозначены как 1 и 0. Отметим, что напряжение холостого хода на узле 1 отрицательно относительно узла 0. PSpice дает для него значение V(1)=-2,9091 В. Команда .TF позволяет вычислить выходное сопротивление относительно V(1), равное 152,7 Ом, что соответствует значению сопротивления на рис. 1.13. Теперь мы можем изменять значение R_L в широких пределах и проводить расчеты для каждого значения вручную.

**** 06/14/99 10:05:31 *********** Evaluation PSpice (Nov 1998) **********

Bridge Circuit for Thevenin

**** CIRCUIT DESCRIPTION

V 4 3 40V

R1 1 2 100

R2 2 0 150

R3 1 4 200

R4 4 0 200

R5 2 3 50 .OP

.ОРТ nopage

.TF V(1) V

.END

NODE VOLTAGE NODE VOLTAGE  NODE VOLTAGE  NODE VOLTAGE

( 1) -2.9091 ( 2) -13.0910 ( 3) -22.5450 ( 4) 17.4550

VOLTAGE SOURCE CURRENTS

NAME CURRENT

V   -1.891E-01

TOTAL POWER DISSIPATION 7.56E+00 WATTS

**** OPERATING POINT INFORMATION TEMPERATURE = 27.000 DEG С

**** SMALL-SIGNAL CHARACTERISTICS

V(1)/V = -7.273E-2

INPUT RESISTANCE AT V = 2.115E+02

OUTPUT RESISTANCE AT V(1) = 1.527E+02

Рис. 1.12. Выходной файл при моделировании схемы на рис. 1.11

Рис. 1.13. Схема со значениями V_Th и R_Th для эквивалентного генератора Тевенина

Применение теоремы Тевенина позволило нам заменить сложную схему простым неидеальным генератором напряжения. И поскольку в этой схеме нет сопротивления нагрузки R_L, не имеет значения, подключим ли мы его к реальной схеме или к эквивалентному генератору. Однако эти две схемы не вполне эквивалентны.

Вернемся, например, к схеме (рис. 1.8), с которой мы начали рассмотрение, при удаленном сопротивлении нагрузки V_Th=50 В и R_Th=216,7 Ом.

При R_L=200 Ом ток составляет 0,12 А. Поскольку этот ток проходит через последовательную цепочку сопротивлений, мощность, потребляемая от источника V_Th, составляет 6 Вт. Поскольку мощность нагрузки равна 2,88 Вт, оставшиеся 3,12 Вт выделяются на внутреннем сопротивлении R_Th. Но в исходной схеме, напряжение источника равно 75 В и ток его составляет 0,33 А. Следовательно, от него потребляется мощность 24,8 Вт. Поскольку мощность, выделяемая в нагрузочном резисторе сопротивлением 200 Ом равна 2,88 Вт, оставшаяся часть мощности рассеивается на трех резисторах Т-образной схемы.

Этот пример показывает, что с энергетической точки зрения исходная схема и генератор Тевенина не эквивалентны.

До сих пор мы работали с источниками питания только одного типа, с источниками напряжения. Однако во многих случаях удобно представлять реальные источники электрической энергии как неидеальные источники тока. 

На рис. 1.14 представлен неидеальный источник напряжения. Его напряжение холостого хода, которое часто называют напряжением идеального источника напряжения, составляет 10 В. В реальных источниках напряжения при увеличении тока нагрузки выходное напряжение падает. Чтобы учесть этот эффект, в схеме замещения последовательно с идеальным источником включается внутреннее сопротивление R_i (в данном случае R_i=5 Ом).

Рис. 1.14. Неидеальный источник напряжения

Схема, кроме того, содержит нагрузочный резистор R_L=15 Ом. Рассчитав значения напряжения V₂₀=7,5 В и тока I_L=0,5 А, попытаемся найти неидеальный источник тока, которым можно было бы заменить неидеальный источник напряжения так, чтобы ток и напряжение на нагрузке не изменились.

Нетрудно проверить, что, заменив неидеальный источник напряжения идеальным источником тока в 2 А и включенным параллельно ему резистором R_i=5 Ом, мы реализуем такой источник. При этом значения двух эквивалентных генераторов связаны соотношением I_S= V_S/R_i. 

На рис. 1.15 приведена схема неидеального источника тока. В ней напряжение и ток нагрузочного резистора такие же, как в схеме на рис. 1.14: V₂₀=7,5 В и I_L=0,5 А. Мощность, выделяемая в нагрузке, равна V₂₀I_L=3,75 Вт. Но эквивалентны ли обе схемы по энергетическим соотношениям? В схеме на рис. 1.14 мощность, потребляемая от V_S, составляла 5 Вт, а в схеме на рис. 1.15, мощность, потребляемая от источника тока, равна 15 Вт. Чтобы объяснить это различие подсчитайте мощность, выделяемую в R_i для обоих случаев.

Рис. 1.15. Неидеальный источник тока, обеспечивающий те же условия в нагрузке, что схема на рис. 1.14 

Решения для цепей, содержащих источники тока, могут быть получены методом узловых потенциалов проще, чем методом контурных токов. Моделирование с помощью Spice основано на методе узловых потенциалов. Вспомните, что каждый узел в Spice должен быть обозначен, а каждый элемент цепи должен быть включен между определенными узлами. Для источников напряжения положительный узел должен быть указан в строке описания первым. Для источников тока первым должен быть указан узел, от которого направлена стрелка внутри обозначения источника. Простейший пример приведен на рис. 1.16. Рассчитаем токи и напряжения в схеме.

Рис. 1.16. Простая цепь с источником тока

Поскольку сопротивление каждой из двух параллельных резистивных ветвей составляет 200 Ом, ток источника в 500 мА делится поровну между ветвями: I₁=I₂=250 мА. Напряжение на R_i равно V₁₀=R_iI₁=200·0,250=50 В. Напряжение на выходе V₂₀=R_LI₂=100·0,250=25 В.

Создадим входной файл и получим решение на PSpice:

Simple Circuit with Current Source

I 0 1 500mA

RI 1 0 200

R1 1 2 100

RL 2 0 100

.OP

.OPT nopage

.TF V(2) I

.END

Отметим, что в качестве обозначения для единицы силы тока с префиксом применяется mA (миллиампер). Иногда вместо этого применяется обозначение М или МА. Будьте осторожны! Символ для мега — это MEG. Ток источника направлен от узла 0 к узлу 1 по стрелке внутри источника. Переходная функция показана для случая, когда выходной величиной является V(2), а входной — ток I. Команда при этом имеет такой же формат, как и в случае определения входного или выходного сопротивления.

Запустите анализ и получите результаты: V(1) = 50 В, V(2) = 25 В. Отметим, что V(2)/I = 50. Эта переходная функция представляет собой отношение выходного напряжения к входному току и имеет размерность сопротивления (Ом). Для данного анализа она не представляет интереса. Входное сопротивление в

100 Ом проверяется просто. Выходное сопротивление составляет 75 Ом и представляет собой сопротивление, которое «видит» нагрузка при неактивном источнике тока. Это означает, что источник тока разомкнут или удален из схемы. Проверьте значение 75 Ом для выходного сопротивления. Выходной файл показан на рис. 1.17

**** 07/27/05 12:15:15 *********** Evaluation PSpice (Nov 1999) **************

Simple Circuit with Current Source

**** CIRCUIT DESCRIPTION

I 0 1 500mA

RI 1 0 200

R1 1 2 100

RL 2 0 100

.OP

.OPT nopage

.TF V (2) I

.END

**** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG С

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 50.0000 ( 2) 25.0000

VOLTAGE SOURCE CURRENTS

NAME CURRENT

TOTAL POWER DISSIPATION 0.00E+00 WATTS

**** OPERATING POINT INFORMATION TEMPERATURE = 27.000 DEG С

**** SMALL-SIGNAL CHARACTERISTICS

V(2)/I = 5.000E+01

INPUT RESISTANCE AT I = 1.000E+02

OUTPUT RESISTANCE AT V(2) = 7.500E+01

Рис. 1.17. Выходной файл при моделировании схемы на рис. 1.16

Рассеиваемая мощность равна 0, что, конечно, неверно. Дело в том, что команда .OР дает рассеиваемую мощность только для источников напряжения. А как же определить общую рассеиваемую мощность в нашем случае? Можно вычислить сумму I²R для всех трех резисторов и проверить, что это и есть суммарная потребляемая мощность, составляющая 25 Вт. Еще проще вычислить произведение тока источника I и напряжения V(1) на его выходе. Проверьте, что и в этом случае расчет дает 25 Вт. 

Теорема Нортона используется, чтобы представлять неидеальные источники в виде идеальных источников тока с шунтирующим резистором, так же как теорема Тевенина представляет их в виде последовательного соединения резистора и идеального источника напряжения. Соотношение между параметрами этих двух моделей задается уравнением:

причем внутренние сопротивления у обеих моделей одинаковы. Ток I_N определяется при закороченной нагрузке. 

Для одних цепей принято находить ток короткого замыкания I_N, для других— напряжение холостого хода V_Th. Когда найдена одна из этих величин, другую можно получить из приведенного выше соотношения.

В схеме на рис. 1.18 ток короткого замыкания можно определить при закорачивании резистора R₄. При этом узел 3 исчезает, поскольку потенциал его сравнивается с потенциалом узла 0. Входной файл для этого случая имеет вид:

Norton's Theorem; Find Isc

V 1 0 48V

R1 1 2 20k

R2 2 0 20k

R3 2 0 5k

.DC V 48V 48V 48V

.OP

.OPT nopage

.PRINT DC I(R3) V(1,2)

.END

Рис. 1.18. Т-образная схема для анализа по теореме Нортона 

Запустите анализ и проверьте, что ток короткого замыкания равен току через R₃ и что I(R3)=1,6 мА.

Вернемся снова к схеме на рис. 1.9, в которой резистор R_L должен быть закорочен, чтобы получить ток короткого замыкания. Проблема, которая при этом возникает, состоит в том, что мы не можем указать элемент схемы, в котором следует определить ток. В подобных ситуациях можно просто заменить R_L резистором с сопротивлением, пренебрежимо малым по сравнению с любым другим сопротивлением схемы. При этом вид входного файла будет:

Norton's Theorem with RL Replaced by Small R

V 1 0 80V

R1 2 1 20

R2 2 3 100

R3 3 0 200

R4 3 4 100

R5 2 4 400

RL 4 0 0.001

.DC V 80V 80V 80V

.OP

.OPT nopage

.PRINT DC I(RL)

.END

Анализ на PSpice дает I(RL)=0,444 А, что и является искомым током короткого замыкания I_N. Включим в последний входной файл команду .TF, чтобы попытаться найти выходное сопротивление относительно V(4). Это сопротивление не должно отличаться от сопротивления R_L=0,001 Ом, которое мы включили в файл для определения тока короткого замыкания.

Мы должны признать, что определение V_Th и R_Th с использованием PSpice намного проще, поскольку в выходном файле можно получить оба значения. В примере на рис. 1.9 I_N=V_Th/R_Th=0,444 А.

Цепи, включающие источники тока и напряжения, могут быть рассчитаны при применении метода наложения. Если цепи не слишком сложны, этот метод дает простое и вполне приемлемое решение. На рис. 1.19 приведена цепь, содержащая источник тока I и источник напряжения V. Применим метод наложения для определения напряжения V₁₀. Проведите расчет самостоятельно, а затем проверьте результат по приведенному ниже решению.

Рис. 1.19. Схема с простыми источниками тока и напряжения 

Напряжение V₁₀(a), которое получается при замыкании источника напряжения, составляет V₁₀(a)=5 В, напряжение V₁₀(b), получающееся от V при размыкании источника тока, равно V₁₀(b)=10 В, и после сложения этих двух значений получим V₁₀=15 В.

Обратимся теперь к анализу схемы на PSpice. Входной файл должен выглядеть следующим образом:

Simple Current and Voltage Sources

I 0 1 1A

V 20 20

R1 1 0 10

R2 1 2 10

.OP

.OPT nopage

.TF V(1) V

.END

Выходной файл дает V(1) = 15 В, что соответствует расчету методом наложения. Команда .TF дает нам возможность найти ток источника напряжения V, равный 0,5 А. Проверьте правильность этого результата. Вспомним, что PSpice дает корректное значение отдаваемой мощности только для источников напряжения, оно просто равно произведению напряжения на ток источника и составляет 10 Вт. Вычислим мощность, рассеиваемую в каждом резисторе: Р₁=22,5 Вт, Р₂=2,5 Вт, что в сумме дает 25 Вт. Команда .TF дает возможность вычислить входное и выходное сопротивления. Проверьте эти значения, учитывая, что при их расчете источник тока следует разомкнуть.

Итак, если в исследуемой цепи есть источники тока, следует осторожно подходить к расчету рассеиваемой мощности, поскольку выходной файл показывает лишь мощность, потребляемую от источников напряжения. Если в схеме несколько таких источников, то в выходном файле приводится суммарная мощность всех источников напряжения.

Для схем, в которых нагрузочное сопротивление может изменяться при функционировании устройства, представляется существенным вопрос: при какой величине нагрузочного сопротивления передаваемая ему мощность будет максимальной? На рис. 1.20 таким нагрузочным сопротивлением является резистор R_L. Когда сопротивление R_L равно сопротивлению схемы относительно выходных узлов (узлов 3 и 0 в нашей схеме), передаваемая в нагрузку мощность будет максимальной.

Рис. 1.20. Схема для определения максимальной мощности, передаваемой в нагрузку 

Выходное сопротивление цепи — это просто сопротивление Тевенина R_Th которое для нашей схемы составляет 30 Ом. Поэтому при R_L=30 Ом в нагрузке рассеивается максимальная мощность. Это означает, что при неизменных параметрах цепи любое изменение R_L в сторону увеличения или уменьшения приведет к снижению выделяемой в нем мощности. И анализ на SPICE может нам это продемонстрировать. Входной файл для такого анализа имеет вид:

Maximum Power Transfer to R Load

V 1 0 12V

R1 1 2 20

R2 2 0 20

R3 2 3 20

RL 3 0 30

.OP

.OPT nopage

.END

Выходной файл показывает V(3) = 3 В, откуда P_L=V(3)²/R_L=0,3 Вт. Теперь можно почувствовать реальные преимущества SPICE, в которой не составляет труда сделать R_L больше или меньше. Изменив в исходном файле только величину R_L и снова проведя анализ, мы быстро увидим новый результат. 

Например, при R_L=29 Ом, V(3)=2,9492 В и P_L=0,2999 Вт. Попытка проверить результат при нескольких различных значениях R_L покажет вам, что мощность всегда меньше 0,3 Вт. Запомните, что максимальная мощность в нагрузочном сопротивлении выделяется тогда, когда оно равно выходному сопротивлению схемы. Это может быть показано при применении теоремы Тевенина для сколь угодно сложных схем.

Из этого примера видно, что компьютерный анализ позволяет яснее представить себе общие принципы, определяющие поведение схем без нудного повторения сложных вычислений.

Зависимые (управляемые) источники могут представлять собой источники тока или напряжения, выходное значение которых зависит от токов или напряжений, возникающих еще где-либо в схеме.

Схема на рис. 1.21 содержит независимый источник напряжения V и зависимый источник напряжения Е c меткой 2V_a. От чего же зависит этот зависимый источник? Его выходное напряжение является функцией напряжения на резисторе R₁, которое обозначается как V_a. Множитель 2 означает, что напряжение Е равно удвоенному значению V_a. В общем виде множитель обозначается как k.

Рис. 1.21. Источник напряжения, управляемый напряжением

Токи и напряжения в схеме могут быть получены с помощью обычных уравнений. Для левого контура второй закон Кирхгофа дает

V = R₁I₁₂ + E = R_II₁₂ + 2V_a,

где I₁₂ — ток через резистор R₁. Поскольку V_a=R₁I₁₂, выражение можно преобразовать к виду:

V = R₁I₁₂ + 2R₁I₁₂ = 3R₁I₁₂;

10 В = 3·(250 Ом)·I₁₂;

I₁₂ = 13,33 мА;

V₁₂ = V_a = R₁I₁₂ = (250 Ом)·(13,33 мА) = 3,333 В;

Е = 2V_a = 6,667 В.

Поскольку это напряжение приложено к R₂, можно найти ток через R₂, а также ток через ветвь, содержащую R₃ и R_L:

Ток через источник Е определяется из первого закона Кирхгофа:

I_Е = 13,33 мА – 66,67 мкА – 6,41 мА = 6,85 мА.

Как такие задачи решаются на PSpice? Входным файлом для схемы на рис. 1.21 будет:

Voltage-Controlled Voltage Sources

V 1 0 10V

Е 2 0 1 2 2

R1 1 2 250

R2 2 0 100k

R3 2 3 40

RL 3 0 1k

.OP

.OPT nopage

.TF V(3) V

.END

Новой командой во входном файле является команда описания зависимого источника напряжения Е. Узлы 2 и 0 являются его положительным и отрицательным полюсами, узлы 1 и 2 являются положительным и отрицательным полюсами напряжения, которое управляет выходным напряжением источника Е. Наконец, последнее число 2 является коэффициентом k. Выходной файл (рис. 1.22) дает значения V(2) = 6,6667 В и V(3) = 6,4103 В, как и было ранее рассчитано. Ток источника напряжения V также равен расчетному значению 13,333 мА. Ток источника питания E равен 6,856 мА и направлен от положительного полюса источника внутри него. 

**** 07/27/05 12:27:16 *********** Evaluation PSpice (Nov 1999) ************

Voltage-Controlled Voltage Sources

**** CIRCUIT DESCRIPTION

V 1 0 10V

E 2 0 1 2 2

R1 1 2 250

R2 2 0 100k

R3 2 3 40

RL 3 0 1k

.OP

.OPT nopage

.TF V(3) V.END

**** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG С

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 10.0000 ( 2) 6.6667  ( 3) 6.4103

VOLTAGE SOURCE CURRENTS

NAME CURRENT

V   -1.333E-02

TOTAL POWER DISSIPATION 1.33E-01 WATTS

**** OPERATING POINT INFORMATION TEMPERATURE = 27.000 DEG С

**** VOLTAGE-CONTROLLED VOLTAGE SOURCES

NAME     E

V-SOURCE 6.667E+00

I-SOURCE 6.856E-03

**** SMALL-SIGNAL CHARACTERISTICS

V(3)/V = 6.410E-01

INPUT RESISTANCE AT V = 7.500E+02

OUTPUT RESISTANCE AT V(3) = 3.846E+01

Рис. 1.22. Выходной файл для схемы на рис. 1.21

Выходной файл дает значение входного сопротивления в 750 Ом. Это просто отношение V к I₁₂. Для определения выходного сопротивления каждый из источников питания необходимо закоротить. При закорачивании узлов 2 и 0 параллельное соединение R₃ и R_L дает сопротивление 8,46 Ом.

На рис 1.23 показана модификация схемы, для которой входной файл имеет вид:

Another Voltage-Controlled Voltage Sources

V 1 0 10V

E 2 0 1 2 2

R1 1 2 250

R2 2 0 100k

R3 3 4 40

RL 4 0 1k

.OP

.OPT nopage

.TF V(4) V

.END

Рис. 1.23. К исследованию схемы с источником напряжения, управляемым напряжением

В этой упрощенной схеме легче рассчитать усилитель напряжения. Ток в левом контуре равен:

Падение напряжения на R2 равно:

V₂ = V_a = I₁₂R₂ =(99,75 мкА)(100 кОм) = 9,975 В;

и

Е = 2V_a = (2) (9,75 В) = 19,95 В.

Из выходного файла находим V(2)=9,9751 В, V(3)=19,95 В и V(4)=19,183 В. Ток через источник питания V составляет 99,75 мкА, а ток через источник Е равен -19,18 мА. Знак минус показывает, что ток внутри источника течет от минуса к плюсу.

Данный источник напряжения управляется током в какой либо ветви схемы, как показано на рис. 1.24. Зависимый источник имеет значение 0,5I, где I — ток через резистор R₁. Ток протекает от узла 1 к узлу 2. Положительный полюс зависимого источника напряжения подключен к узлу 3, что дает в правом контуре направление тока по часовой стрелке. Это необходимо отметить, поскольку направление токов играет важную роль в расчетах.

Рис. 1.24. Схема с источником напряжения, управляемым током

Схему несложно рассчитать. В левом контуре источник в 15 В создает ток I=V/(R₁+R₂)=15/(10+5)=1 А. Зависимый источник напряжения обозначен как 0,5I. Его ток будет 0,5·1=0,5 В. Таким образом, V₃₀=0,5 В. Как вдруг появилась размерность напряжения? Дело в том, что коэффициент k не безразмерный, он имеет размерность Ом. В общем, для этого источника напряжения, управляемого током (ИНУТ), следует применить запись kI. Коэффициент к выражается в омах, поэтому произведение k и I даст вольты.

Ток в правом контуре находится как I_L=0,5/(25+25)=10 мА, а напряжение V₄₀=I_LR_L=0,25 В.

Используя PSpice, решим эту задачу в качестве подготовки к расчету другой, более сложной схемы. Входной файл содержит командную строку для описания ИНУТ (CDVS — Current-Dependent Voltage Source) и имеет следующий вид:

Circuit with Current-Dependent Voltage Sources

V 1 0 15V

H 3 0 V -0.5

R1 1 2 10

R2 2 0 5

R3 3 4 25

R4 4 0 25

.OP

.OPT nopage

.TF V(4) V

.END

Внимательно следите за тем, чтобы командная строка для ИНУТ начиналась с символа Н. На той же строке 3 и 0 означают номера положительного и отрицательного полюсов источника питания. Следующий символ V обозначает независимый источник, через который протекает управляющий ток I. И последней записью этой строки является –0,5. Здесь 0,5 — величина коэффициента k, а знак «минус» требует пояснения. В SPICE ток источника напряжения (например ток через V) положителен, если внутри источника он течет от плюса к минусу. Поскольку управляющий ток течет в обратном направлении, коэффициент k в источнике H отрицателен. Если знак «минус» будет опущен, напряжения V(3) и V(4) будут иметь в выходном файле неверные знаки. 

Если вы уверены, что готовы продолжать, запустите анализ на PSpice и получите выходной файл. Отметим, что V(3)=0,5 В и V(4)=0,25 В. Ток источника V равен I=-1,0 А. Это означает, что ток течет от плюса источника V и на рис. 1.24 он положителен. Таким образом, положительно и V(3).

Вспомним также, что значение, показанное в выходном файле, равно просто VI, а не представляет собой действительную полную мощность. В разделе выходного файла, названном Current-Controlled Voltage Sources, имеется две строки ввода. Первая вводит источник V c напряжением 0,5 В. Это — значение напряжения независимого источника напряжения. Сложнее запись второй строки, которая дает значение тока -10 мА. Можете вы понять, что это означает? Это означает, что ток через ИНУТ равен 10 мА и протекает внутри источника от плюса к минусу, в соответствии с соглашением Spice относительно тока источника, которое мы уже знаем. Входное напряжение относительно V в выходном файле рано 15 Ом, выходное сопротивление относительно V(4) составляет 12,5 кОм.

Другим типом зависимых источников, который часто применяется в электронике, является источник тока, управляемый током (ИТУT) (Current-Controlled Current Source (CCCS) или Current-Dependent Current Source (CDCS)).

На рис. 1.25 показана базовая схема. Значение источника тока равно 3I, где I — ток через резистор R₁. Как и в предыдущем примере, ток протекает от узла 1 к узлу 2, по часовой стрелке в левом контуре. Коэффициент 3I обычно задается как kI, где k — множитель для опорного тока, протекающего в одной из ветвей цепи. Нетрудно установить, что при I=2 А в левом контуре ток через F будет равен 3·2=6 А и проходит в направлении, указанном стрелкой внутри F.

Рис. 1.25. Схема с источником тока, управляемым током 

В этом примере мы можем получить для I=20/(1500+2500)=5 мА, как и для тока в левом контуре. Ток в F при этом равен 3·5 мА=15 мА (направлен вниз по стрелке). Этот ток делится поровну между R₃ и R₄, по 7,5 мА через каждый резистор. Ток идет от узла 1 к узлу 3, обеспечивая узлу 3 отрицательный потенциал. Напряжение V(3)=-500·7,5 мА=–3,75 В.

В качестве прелюдии к исследованию более сложной схемы с зависимым источником, рассмотрим, как выглядит входной файл для схемы на рис. 1.25:

Current-Controlled Current Sources

V 1 0 20V

F 3 0 V -3

R1 1 2 1500

R2 2 0 2500

R3 3 0 500

R4 3 0 500

.OP

.OPT nopage

.TF V(3) V

.END

Ваш выходной файл должен показать что V(2)=12,5 В и V(3)=-3,75 В. Под заголовком Current-Controlled Current Sources расположена строка ввода тока источника F, дающая значение 15 мА. Поскольку он втрое больше тока в левом контуре, это значение правильное. Положительное значение показывает, что ток направлен от узла 3 к узлу 0 внутри F. Необходимо показать соответствующее значение для F в команде входного файла. На строке, описывающей F, заданы два значения для начального и конечного узла (по стрелке внутри F). Следующее значение V относится к источнику напряжения, который обеспечивает управляющий ток I. Этот ток I входит в выражение для выходного тока источника kI. Коэффициент k является множителем при I, он не имеет размерности. В этом примере к имеет значение -3, которое описывает ток через источник V так же, как в различных предыдущих примерах. Внимательно изучите этот простой пример, поскольку здесь часто возникают ошибки. Освоив этот простой пример, вы будете в состоянии моделировать и более сложные схемы.

В выходном файле для R_IN дано значение 4 кОм, которое, очевидно, верно. Обычно также интересно и выходное сопротивление R_OUT=250 Ом. В самой правой части схемы на рис. 1.25 мы видим два параллельно соединенных сопротивления R₃ и R₄, которые и образуют выходное сопротивление при неактивном (разомкнутом) источнике тока.

Несколько иная ситуация для более сложной схемы с ИТУТ часто возникает при анализе электронных цепей, когда управляющий ток проходит в ветви, не содержащей независимых источников напряжения V. На рис. 1.26, а представлена типовая схема. В ней управляющий ток проходит через резистор R₃. Именно этот ток, умноженный на k, определяет ток источника F.

Напомним, что в строке описания источника F присутствует независимый источник напряжения типа V. Как же быть? Просто введите источник напряжения с нулевым значением в ветвь, в которой протекает управляющий ток, как показано на рис. 1.26, б. Обозначьте этот источник как R₀, чтобы это напоминало вам о его нулевом значении. Входной файл будет иметь вид:

Another CDCS Example

V 1 0 35V

V0 2А 2 0V

F 3 0 V0 -3

R1 1 2 100

R2 2 0 500

R3 2A 0 500

R4 3 0 500

R5 3 0 500

.OP

.ОРТ nopage

.TF V(3) V

.END

Рис. 1.26. Введение источника нулевого напряжения:

а) другая схема с источником тока, управляемым током

б) схема с введенным источником нулевого напряжения

Рассмотрим строку, описывающую F. Она следует за описанием независимого источника V₀, поскольку он находится в ветви, где протекает управляющий ток I. Сравним строки, описывающие F в этом и в предыдущем примерах, чтобы увидеть разницу. Отметим дополнительную строку, описывающую V₀. В ней указаны два узла 2А и 2. Заметим, что положительный узел (всегда первый) показывает направление, приведенное на рисунке. Это соответствует соглашениям, использованным в предыдущих примерах, где ток также выходит из положительного узла источника.

Ранее мы не использовали буквы для обозначения узлов, но это успешно можно делать. На самом деле могут быть использованы комбинации из букв и цифр. Узлы могут быть, например, обозначены как a1, b12, 1с и так далее. Итак, в действительности нулевое значение напряжения означает, что оно не влияет на процессы в схеме. Строка, описывающая R₃, изменена, чтобы показать наличие нового узла 24. 

Запустите моделирование и проверьте результат. Значения равны: V(2)=25 В, V(3)=-37,5 В, и, как ожидалось, V(2A) также равно 25 В. Нетрудно проверить, что I=50 мА, обеспечивая 3I=150 мА, как показано в выходном файле; это и есть ток через F. Этот ток делится поровну между R₄ и R₅, давая ток 75 мА в каждом из них. Таким образом, потенциал V(3)=-75 В. Входное и выходное сопротивления уже проверены.

В качестве дополнительного упражнения посмотрите, что произойдет, если изменить две строки входного файла следующим образом:

V0 2А 2 0V

F 3 0 V0 3

Это просто другой способ описания отношения между управляющим током и ИТУТ (CDCS). Попытайтесь установить, что оба способа равноценны, и применяйте тот, который удобен для вас.

Строка описания источника тока, управляемого напряжением в Spice, начинается буквой G. На рис. 1.27 показан пример такой схемы. Эта цепь легко анализируется с помощью ручного расчета. Напряжение n₂ получается на выходе делителя напряжения и равно 9 В. Ток через зависимый источник равен, таким образом: 0,02·9=180 мА. Коэффициент к имеет размерность проводимости 1/Ом. Этот ток делится поровну между R₃ и R₄, обеспечивая ток 90 мА через каждый резистор. Это дает напряжение

V₃₀ = -0,09·200 = -18 В.

Рис. 1.27. Схема с источником тока, управляемым напряжением 

Входной файл для этого случая:

Voltage-Dependent Current Source

V 1 0 12V

G 3 0 2 0 0.02

R1 1 2 200

R2 2 0 900

R3 3 0 200

R4 3 0 200

.OP

.ОРТ nopage

.TF V(3) V

.END

В строке описания источника тока G приведены сначала два узла: 3 и 0. Они соответствуют началу и концу стрелки в обозначении источника. Следующие два узла (2 и 0) соответствуют плюсу и минусу управляющего напряжения n₂. 

Запустите моделирование на PSpice и проверьте полученные значения величин: V(2)=9 В, V(3)=-18 В, V(2)=25 В, R_IN=1200 Ом и R_OUT=100 Ом.

Отношение V(3)/V=-1,5 представляет собой коэффициент усиления схемы. В дальнейшем вы увидите, как эта величина может использоваться для анализа различных транзисторных и интегральных схем.

Вспомним, что источники напряжения, управляемые токами в какой-либо ветви, называются управляемыми током (ИНУТ) или зависимыми от тока (CCVS или CDVS). На рис. 1.28 приведена типовая схема такого источника, отличная от предшествующей. Управляющим током в этом примере является ток i₂, протекающий через резистор R₃ (к узлу 0). ИНУТ обозначается символом Н. Значение k в этом случае составляет 400. Рассчитаем ток источника V, получим I_S=15/(50 + 250) = 50 мА. Этот ток делится поровну между резисторами R₂ и R₃, обеспечивая протекание управляющего тока I₂=25 мА. Напряжение источника Н составляет при этом 400·25 мА=10 В. Ток в правом контуре схемы равен 10/200=50 мА.

Рис. 1.28. Схема с источником напряжения, управляемым током

Входной файл PSpice имеет вид:

Current-Controlled Voltage Source

V 1 0 15V

V0 2A 2 0V

H 3 0 V0 -400

R1 1 2 50

R2 2 0 500

R3 2A 0 500

R3 3 4 50

R4 4 0 150

.OP

.OPT nopage

.TF V(4) V

.END

Запустите моделирование на PSpice и убедитесь, что величины V(2)=2,5 В, V(3)=10 В и V(4)=7,5 В. Команда PSpice, вводящая H, дает узлы 3 и 0 в качестве плюса и минуса управляющего напряжения. На рисунке приведен также источник V₀ в цепи управляющего тока i₂. Полярность этого источника дает направление тока i₂, показанное на рис. 1.28. Последнее значение в командной строке, вводящей H, дает –400 для множителя k. Знак минус необходим, как и в предыдущем примере, чтобы обеспечить правильное направление тока через источник.

Отметим, что выходной файл дает для тока через источник -50 мА, что означает протекание тока от положительного полюса V, и -25 мА для управляющего тока, протекающего от положительного полюса V₀. Под строкой заголовка Current-Controlled Voltage Source в выходном файле приведено значение 10 В, показанное как источник напряжения V. Значение -50 мА, показанное как источник тока I представляет собой ток источника Н. И снова знак минус означает, что ток внутри H течет от минуса к плюсу.

Итак, мы рассмотрели зависимые источники четырех типов E (VCVS или ИНУН — источник напряжения, управляемый напряжением), F (CCCS или ИТУТ — источник тока, управляемый током), G (VCCS или ИТУН — источник тока, управляемый напряжением) и H (CCVS или ИНУТ — источник напряжения, управляемый током). Зависимые источники играют важную роль при анализе большинства схем с активными приборами, такими как транзисторы. Они дают возможность достаточно просто рассчитывать такие схемы, открывая путь к пониманию работы сложных устройств. При этом основные идеи лучше всего можно понять при исследовании цепей постоянного тока, которое проводится в данной главе.

Материал этой главы обычно не включается в общие программы обучения. Если полиномиальные источники не интересуют вас в настоящий момент, вы можете пропустить этот раздел, перейдя сразу к разделу, посвященному методу контурных токов.

Возможности применения для анализа нелинейных зависимых источников лучше всего рассмотреть на конкретном примере, приведенном на рис. 1.29. На нем показан источник напряжения V, питающий два последовательно включенных резистора R₁=R₂=1 кОм. Источник ИНУН обозначен как Е, но в нашем случае напряжение Е связано с управляющим напряжением не просто постоянным коэффициентом k. Предполагается, что Е связано с напряжением V₂₀ нелинейной зависимостью, задаваемой полиномом

Рассмотрим теперь, как вводятся в командной строке, использующей зависимые источники (POLY), управляемые более чем одним напряжением. В примере, представленном на рис. 1.29, сделаем Е функцией сразу двух напряжений v₁ и v₂. Для этого в командной строке следует записать POLY(2) 2,0 4,0. Запятые приведены для ясности и могут быть опущены. В оставшейся части строки должны быть приведены коэффициенты. При двух управляющих напряжениях необходимо ввести шесть коэффициентов: k₀, k₁v₁, k₂v₂, k₃v₁², k₄v₁v₂ и k₅v₂². Эта последовательность более сложна и требует некоторого изучения. Коэффициенты k представляют собой множители для каждого возможного напряжения и для их комбинаций. Напряжения перечисляются в порядке возрастания степени, начиная с первого напряжения, обозначенного как v₁. В нашем примере v₁ является напряжением V₂₀, a v₂ представляет собой V₄₀.

Приведем теперь командную строку, вводящую источник, управляемый двумя напряжениями:

Е 3 0 POLY(2) 2,0 4,0 0 2 3

Последние три значения (0 2 3) представляют собой значения коэффициентов k₀, k₁ и k₂. Они устанавливают полином (0+2v₁+3v₂). Таким образом, напряжение зависимого источника Е представляет собой сумму удвоенного падения напряжения на R₂ и утроенного падения напряжения на R₄. Отметим снова, что запятые внесены для ясности и их можно опустить. Входной файл имеет вид:

Polynomial Form for Two Inputs

V 1 0 1V

E 3 0 POLY(2) 2,0 4,0 0 2 3

R1 1 2 1k

R2 2 0 1k

R3 3 4 2k

R4 4 0 2k

.DC V -4 4 1

.PRINT DC V(2) V(3) V(4)

.END

Запустим моделирование и убедимся, что Е задается выражением (2V₂₀+3V₄₀). Вы можете использовать такой зависимый источник в схемах, в которых появляются суммы, разности или произведения различных токов и напряжений. Использование зависимых источников типа Е, F, G и Н с обозначением POLY позволяет моделировать источники, получая выходные файлы, подобные приведенному на рис. 1.31.

**** 07/27/05 10:54:26 ******** Evaluation PSpice (Nov 1999) **********

Polynomial Form for Two Inputs

**** CIRCUIT DESCRIPTION

V 1 0 1V

E 3 0 POLY(2) 2,0 4,0 0 2 3

R1 1 2 1k

R2 2 0 1k

R3 3 4 2k

R4 4 0 2k

.DC V -4 4 1

.PRINT DC V(2) V(3) V(4)

.END

**** 07/27/05 10:54:26 ******* Evaluation PSpice (Nov 1999) ***********

Polynomial Form for Two Inputs

**** DC TRANSFER CURVES TEMPERATURE = 27.000 DEG С

 V          V(2)       V(3)       V(4)

-4.000E+00 -2.000E+00  8.000E+00  4.000E+00

-3.000E+00 -1.500E+00  6.000E+00  3.000E+00

-2.000E+00 -1.000E+00  4.000E+00  2.000E+00

-1.000E+00 -5.000E-01  2.000E+00  1.000E+00

 0.000E+00  0.000E+00  0.000E+00  0.000E+00

 1.000E+00  5.000E-01 -2.000E+00 -1.000E+00

 2.000E+00  1.000E+00 -4.000E+00 -2.000E+00

 3.000E+00  1.500E+00 -6.000E+00 -3.000E+00

 4.000E+00  2.000E+00 -8.000E+00 -4.000E+00

Рис. 1.31. Вид выходного файла при анализе схемы на рис. 1.29 с двумя управляющими напряжениями

Традиционные курсы электротехники обычно излагают метод контурных токов, использующий контуры и контурные токи для вычисления токов в ветвях схемы.

Стандартная форма уравнений для трех контурных токов имеет вид:

R₁₁I₁ + R₁₂I₂ + R₁₃I₃ = V₁;

R₂₁I₁ + R₂₂I₂ + R₂₁I₃ = V₂;

R₃₁I₁ + R₃₂I₂ + R₃₁I₃ = V₃.

где R₁₁ — собственное сопротивление контура 1; R₁₂ — взаимное сопротивление контуров 1 и 2; R₁₃ — взаимное сопротивление контуров 1 и 3, а V₁ — контурная ЭДС контура 1; алгебраическая сумма всех ЭДС, действующих в контуре 1 (положительными считаются ЭДС, направление которых совпадает с направлением обхода контура). Аналогично составлены уравнения и для контуров 2 и 3. Ручной расчет системы трех уравнений с тремя неизвестными утомителен и часто приводит к ошибкам в вычислениях. Если же число уравнений больше трех, то вычислительная работа становится очень тяжелой. Для выполнения такой работы применяются многочисленные версии компьютерных программ.

А можно ли решить такую систему уравнений с помощью SPICE? Если рассматривать общий случай, то ответ будет отрицательным. Однако можно использовать некоторые приемы, чтобы выполнить такое моделирование, как в следующем примере (рис. 1.32). Здесь имеется три контура. Вы можете составить систему из трех уравнений в стандартном формате и вычислить затем I₁, I₂ и I₃.

Рис. 1.32. Анализ методом контурных токов на PSpice

Вы можете сделать это и в качестве упражнения перед просмотром следующего входного файла:

Mesh Analysis with PSpice

V1 1 0 50V

V2 4 0 30V

R1 1 2 100

R2 2 0 200

R3 2 3 400

R4 3 0 200

R5 3 4 100

.OP

.OPT nopage

.DC V1 50 50 10

.PRINT DC I(R1) I(R2) I(R3)

.END

Во входной файл включены две интересные команды. Первая из них — это команда .DC. Это команда вариации по напряжению V₁, которая была введена при исследовании примера, касающегося теоремы Нортона. Она позволяет изменять напряжение V₁. Следующие два значения (50 и 50) задают начальное и конечное значение при вариациях. Поскольку они одинаковы, это практически означает отказ от вариации. Если же вы действительно хотите изменять напряжение с шагом от 10 до 50 В, то команду необходимо заменить следующей:

.DC V1 0 50 10

Однако вариация нас пока не интересует, и мы оставим команду в прежнем виде, вычисляя токи только при одном значении напряжения V₁. Определить диапазон вариации мы вынуждены для реализации последующей команды .PRINT, чтобы получить значения тока I(R1) и напряжения V(2,3). Если не включить команду .DC перед командой .PRINT, последняя будет выполнена некорректно. Запустим моделирование и проверим результат. В выходном файле получены значения I(R1)=0,1833 A; I(R3)=25 мА и I(R5)=-83,33 мА. Это и есть три контурных тока, которые мы должны получить, решая три уравнения, составленные по методу контурных токов. На самом деле анализ, применяемый в PSpice, более похож на метод узловых потенциалов, но используя дальнейшие расчеты, можно получить и контурные токи (так же, как и токи в ветвях).

Поскольку в задачах на применение контурных токов мы столкнулись с проблемой вариации параметров на постоянном токе (dc sweep), рассмотрим пример, в котором такая вариация используется нормальным образом, в некотором диапазоне напряжений. Используем знакомую нам Т-образную схему на рис. 1.33.

Рис. 1.33. Т-образная схема, в которой проводится вариация напряжения

Без всякого предварительного анализа рассмотрим входной файл для PSpice:

Spice Sweep Analysis of Tee Circuit

V1 1 0 50V

R1 1 2 100

R2 2 3 50

R3 2 0 200

R4 3 0 150

.OP

.OPT nopage

.TF V(3) V

.DC V1 0 50 10

.PRINT DC V(2,3) I(R3)

.END

Вариация напряжения начинается от нуля вольт и производится до 50 В с шагом в 10 В. В выходном файле строятся две таблицы, в одной из которых показана зависимость V(2,3) от V, а в другой — зависимость I(R3) от V, как и требует команда .PRINT. Запустите моделирование на PSpice и просмотрите результат. Какого размера таблицы необходимо здесь использовать? Если вы хотите определить, какое напряжение соответствует току зависимости I(R3)=50 мА, то таблицы дадут значение напряжения 20 В. Вы, конечно, можете легко рассчитать результат, но если точек будет много, то PSpice может выполнить эту работу за вас.

Пакет MicroSim включает также программу Probe, применение которой было проиллюстрировано во введении. Программу можно запустить, выбрав пиктограмму Probe на рабочей панели MicroSim или включив во входной файл команду .PROBE.

Чтобы проиллюстрировать, как правильно работать с этой командой, рассмотрим снова Т-образную схему, несколько изменив входной файл и дав ему имя satc.cir (Sweep Analysis Tee Circuit).

Sweep Analysis of Tee Circuit

V1 1 0 50V

R1 1 2 100

R2 2 3 50

R3 2 0 200

R4 3 0 150

.OP

.OPT nopage

.TF V(3) V

.DC V1 0 50 10

.PROBE

.END

После окончания моделирования вы можете просмотреть выходной файл и выбрать графики, которые вам хотелось бы получить. Для подготовки к построению графиков выберите View, проигнорировав View Output Window и Simulating Status Window.

Из основного меню выберите Trace, Add Trace и вы увидите новый экран с выходными параметрами, такими как напряжения V, V(1), V(2) и V(3), токи I(R₁), I(R₂) и так далее. Выберите I(R₃) и, повторив процесс, выберите I(R₁). Вы получите график зависимости этих двух токов от напряжения V в диапазоне от 0 до 50 В.

Желательно получить распечатку результатов, но если вы захотите также нанести на графики поясняющие надписи, используйте команды Plot, Label, Text и наберите необходимый текст в соответствующем поле. Затем нажмите OK. С помощью мыши перетащите появившийся текст в необходимую точку экрана. Вы должны получить вид экрана в соответствии с рис. 1.34.

Рис. 1.34. Зависимости токов IR₃ и IR₁ от напряжения питания, полученные с помощью функции .Probe

Чтобы ознакомиться с еще одной интересной возможностью, выберите Trace, Cursor, Display, чтобы вызвать окно Probe Cursor. Вы увидите табло:

А1 = 0.000, 0.000

А2 = 0.000, 0.000

dif = 0.000, 0.000

показывающее значения, соответствующие положению курсора в начале координат. Подведите с помощью мыши курсор к точке, соответствующей примерно 15 В на оси X, затем с помощью стрелок ← и → на клавиатуре переместите точку точно в 15 В. На табло должны появиться цифры:

А1 = 15.000, 37.500m

А2 = 0.000, 0.000

dif = 15.000, 37.500m

Координаты А1 представляют собой напряжение V и ток I(R3) в выделенной точке. Затем нажмите Ctrl и стрелку → на клавиатуре, чтобы перейти к другой кривой, и проверьте, что при V=15 В ток I(R1) = 75,0 мА. Вспомним, что вариации проводились для значений V, равных 0, 10, 20, 30, 40 и 50 В. Программа Probe автоматически проводит анализ кривых, чтобы рационально разместить все полученные точки на экране.

Чтобы рассмотреть другой интересный пример использования программы Probe, вернемся к примеру рис. 1.30, где была показана схема с полиномиальным зависимым источником напряжения. Добавьте команду .PROBE во входной файл и снова запустите моделирование. Теперь вместо таблиц результатов в выходном файле используйте Probe, чтобы построить график зависимости V(2), V(3), V(4). Поработайте с кривыми, пока не почувствуете, что свободно пользуетесь функциями Probe. Используйте Trace, Cursor, Display, чтобы проверить численные результаты, сравнив их с полученными при помощи команды .PRINT.

В программе Probe имеется много других возможностей, которые будут продемонстрированы в процессе рассмотрения примеров в тексте.

Традиционные курсы электротехники обычно излагают метод узловых потенциалов, используя стандартные уравнения. Эти уравнения гораздо легче записать, если все неидеальные источники напряжения заменить неидеальными источниками тока. Это имеет тот недостаток, что цепь физически изменяется, но за счет этого уменьшается количество узлов и, соответственно, количество уравнений. После нахождения узловых потенциалов вы можете провести обратное преобразование источников, приведя схему снова к исходной. Стандартная форма уравнений для узловых потенциалов:

G₁₁V₁ + G₁₂V₂ + G₁₃V₃ = I₁;

G₂₂V₂ + G₂₂V₂ + G₁₃V₃ = I₂;

G₃₁V₁ + G₃₂V₂ + G₃₃V₃ = I₃,

где G₁₁ — собственная проводимость узла 1; G₁₂ — взаимная проводимость узлов 1 и 2; G₁₃ — взаимная проводимость узлов 1 и 3, а I₁ — ток узла 1, алгебраическая сумма всех токов, походящих к узлу 1. В методе узловых потенциалов все собственные проводимости положительны, а все взаимные проводимости отрицательны.

Схема на рис. 1.35 будет использована для анализа по методу узловых потенциалов. В качестве упражнения запишите уравнения по этому методу и решите их с помощью какой-либо компьютерной программы или калькулятора. Записать стандартные уравнения и решить их полезно, но решать их каждый раз неэффективно.

Рис. 1.35. Схема с несколькими источниками тока для анализа методом узловых потенциалов

Решение с помощью PSpice достаточно просто и не содержит ничего нового. Входной файл имеет вид:

Nodal Analysis of Circuit with Several Current Sources

I1 1 0 20mA

I2 0 2 10mA

I3 0 3 15mA

R1 1 0 500

R2 1 2 500

R3 2 0 400

R4 2 3 500

R5 3 0 300

.OP

.ОРТ nopage

.END

Во входном файле достаточно информации, чтобы найти все узловые потенциалы. Запустим моделирование и проверим напряжения V(1)=7,694 В; V(2)=5,3947 В и V(3)=4,8355 В. Значение общей рассеиваемой мощности, приведенное в выходном файле, равно 0, что, очевидно, некорректно. Напомним, что это происходит, поскольку в схеме нет независимых источников напряжения.

Чтобы получить правильное значение, преобразуйте источники тока (рис. 1.35) в источники напряжения и создайте входной файл для получившейся схемы (рис. 1.36).

Рис. 1.36. Преобразование неидеальных источников тока в неидеальные источники напряжения

На этом, последнем, рисунке к узлам 1, 2 и 3 подключены те же самые сопротивления, что и в предыдущей схеме, но появились три дополнительных узла, что привело к соответствующему изменению входного файла:

Nodal Analysis with Current Sources Converted to Voltage Sources

V1 1A 0 10V

V2 2A 0 4V

V3 3А 0 4.5V

R1 1A 1 500

R2 1 2 500

R3 2 2A 400

R4 2 3 500

R5 3 3А 300

.OP

.OPT nopage .END

После получения результатов моделирования убедитесь, что V(1) = 7,694 В, V(2) = 5,3947 В и V(3) = 4,8355 В, как и ранее. Для трех дополнительных узлов напряжения будут равны: V(1A) = 10 В; V(2A) = 4 В и V(3A) = 4,5 В, как указано во входном файле для идеальных источников напряжения. В дополнение к этому вы можете определить три тока источников. Например, ток через V₁ равен –4,605 мА. Это означает, что положительный ток 4,605 мА вытекает из положительного полюса источника V₁. Проверьте, что остальные токи вычислены правильно. Поскольку все источники являются источниками напряжения, общая мощность вычислена верно и равна 27,1 мВт.

Если схемы непланарны, их нельзя изобразить в двухмерном пространстве без пересечения линий, соединяющих узлы. Такова схема на рис. 1.37, которая содержит источник напряжения и восемь резисторов, то есть всего девять элементов. Из используемых методов расчета метод контурных токов может быть использован только для планарных схем, однако метод узловых потенциалов может быть использован и для непланарных схем. PSpice является инструментом, наиболее часто применяемым для анализа схем с большим числом элементов. Для исследуемой схемы входной файл имеет вид:

Nonplanar Circuit Containing Nine Elements

V 1 0 9V

R1 1 2 1

R2 4 0 7

R3 3 0 5

R4 2 3 6

R5 5 3 4

R6 2 4 2

R7 1 5 8

R8 4 5 3

.DC V 9V 9V 9V

.PRINT DC V(1,2) V(2,3) V(2,4)

.PRINT DC V(4,5) V(5,3) V(1,5)

.OP

.OPT nopage

.END

Рис. 1.37. Непланарная схема

Во входном файле предусмотрено вычисление напряжений на отдельных элементах, которые желательно знать, чтобы определить токи в ветвях. С другой стороны, в команде .PRINT можно заложить распечатку токов через резисторы, например I(R1). Отметим, что без введения команды .ОР узловые потенциалы не могут быть получены. Убедитесь, что V(1,2)=1,367 В; V(2,4)=1,685 В; V(1,5)=3,031 В. Проведите также численную проверку равенства V(1)=V(1,2)+V(2,3)+V(3).

В квадратные скобки […] заключаются необязательные компоненты, в угловые скобки <…> — компоненты, которые необходимо ввести обязательно.

Е[имя] <+узел> <-узел> <[+управляющий узел> <-управляющий узел]> коэффициент усиления>

Например, запись

Е 2 3 1 0 5

обозначает источник напряжения, управляемый напряжением (ИНУН), включенный между узлами 2 и 3 (2 — плюсовой узел), зависящий от напряжения между узлами 1 и 0. Напряжение Е равно 5V₁₀.

F[имя] <+узел> <-узел> <Имя управляющего прибора V> <коэффициент усиления>

Например, запись

F 4 2 VA 50

обозначает источник тока, управляемый током (ИТУТ), включенный между узлами 4 и 2, с током, протекающим внутри источника от узла 4 к узлу 2. Ток зависит от тока через источник VA с коэффициентом усиления 50. Если необходимо, напряжение VA может быть выбрано нулевым.

G[имя] <+узел> <-узел> <+управляющий узел> <-управляющий узел> <коэффициент усиления>

Например, запись

G 5 1 2 0 0.05

обозначает источник тока, управляемый напряжением (ИТУН), включенный между узлами 5 и 1, зависящий от напряжения между узлами 2 и 0. Значение коэффициента усиления g_m=0,05 С (коэффициент имеет размерность проводимости 1/Ом)

Н[имя] <+узел > <-узел> <Имя управляющего прибора V> <переходное сопротивление>

Например, запись

Н 6 4 VB 20

обозначает источник напряжения, управляемый током (ИНУТ), включенный между узлами 6 и 4 (6 — плюсовой узел), зависящий от тока, протекающего через источник напряжения VB, напряжение которого может быть выбрано при необходимости нулевым. Значение переходного сопротивления равно 20 Ом.

I[имя] <+узел> <-узел> [DC] <значение>

Например, запись

I 0 1 DC 2А

обозначает независимый источник постоянного тока, направленного внутри источника от узла 0 к узлу 1. Значение тока равно 2 А. 

R[имя] <+узел> <-узел> <значение>

Например, запись

R1 1 2 100

обозначает резистор, включенный между узлами 1 и 2 с сопротивлением 100 Ом. Поскольку резистор двунаправленный, любой его узел можно назвать положительным или отрицательным. Если необходимо найти ток через резистор, обозначение узлов становится немаловажным. В данном примере условное направление тока через резистор принимается от узла 1 к узлу 2. При таком направлении реального тока он считается положительным, при противоположном — отрицательным. В выходном файле значение тока будет иметь соответствующий знак.

V[имя] <+узел> <-узел> [DC] <значение>

Например, запись

V 1 0 50V

обозначает независимый источник напряжения с положительным полюсом у узла 1 и отрицательным — у узла 0. Это — идеальный источник напряжения с напряжением 50 В. Обозначение DC не является обязательным. Обозначение единиц V, следующее за числом, обозначающим выходное напряжение, также необязательно, по умолчанию оно выражается в вольтах. Другие формы команд, вводящих V, приведены в главах 2, 3, 4 и др. Одни из них вводят источники переменного напряжения, другие — источники с заданными временными зависимостями.

.DC [LIN] [OCT] [DEC]<переменная вариации> <начало> <конец> <шаг>

Например,

.DC LIN VS 0V, 10V 0.1V

означает, что напряжение источника напряжения VS будет варьировать от 0 до 10 В с шагом 0,1 В. Вариация напряжения линейная.

.END

Эта команда должна стоять в конце входного файла и информировать программу PSpice об отсутствии дальнейших команд в данном файле.

.ОР

Эта команда используется для вывода детальной информации о точках смещения.

.OPTION

Например,

.OPTION nopage

означает выбор опции, при которой отсутствуют колонтитулы страниц и пробелы при печати каждого раздела выходного файла. Другие возможные опции:

АССТ — для вывода информации расчета

LIST — дает информацию об использованных в схеме приборах

NODE — выводит таблицу узлов

NOECHO — подавляет вывод входного файла

NOMOD — подавляет вывод параметров моделей

OPTS — показывает использованные опции

WIDTH — показывает число столбцов вывода 

.PRINT DC <переменные вывода>

Например,

.PRINT DC V(5) I(RL)

показывает, что должны быть выведены напряжение узла 5 V(5) и ток I(RL) через резистор RL.

.PROBE

показывает, что при анализе должна быть использована программа построения графиков Probe. В этой программе могут быть построены все зависимости для токов и напряжений. Границы могут быть заданы для входных напряжений, либо, в случае анализа на переменном токе, для частоты.

При выводе графиков могут быть использованы выражения для выходных переменных. Чаще всего используются простые операторы: +, -, /, * (сложение, вычитание, деление и умножение). Могут быть также использованы функции ABS(x), SGN(x), DB(x), ЕХР(х), LOG(x), LOG10(x), PWR(x), SQRT(x), SIN(x), COS(x), TAN(x), ARCTAN(x), d(x), s(x), AVG(x) и RMS(x).

.TF <переменные вывода> <входной источник>

Например,

.Т F V (5) VS

означает, что будет выведена переходная функция V(5)/VS. Она является переходной функцией для малых сигналов. Применяется также для вывода входных и выходных сопротивлений схемы.

POLY (полиномиальные источники)

Например,

Е1 5 2 3 POLY (1) 3 1 1 2 3

означает, что ИНУН Е1 связан с напряжением между узлами 3 и 1 нелинейной зависимостью, описываемой полиномом. (1) здесь означает, что имеется только одно управляющее напряжение V₃₁. Три следующих значения задают коэффициенты полинома k₀, k₁ и k₂ в формуле

k₀ + k₁v₁+ k₂v₁².

Если задано больше значений k, то это означает, что полином будет более высокой степени. 

Если строка во входном файле начинается со звездочки (*), то она является строкой комментария, а не исполняемой команды. Комментарий может быть помещен также в конце командной строки после точки с запятой (;). При описании команд PSpice в квадратные скобки […] заключаются необязательные компоненты, в угловые скобки <…> — компоненты, которые необходимо ввести обязательно. Если в конце командной строки помещена звездочка, это означает, что компонент может повторяться.

1.1. Для схемы на рис. 1.38 найдите ток I. Ваш входной файл на PSpice должен включать команды для непосредственного вывода тока. Проверьте результат, найдя ток из выражений V₁₂/R₁ и V₂₃/R₂.

Рис. 1.38

1.2. Для схемы на рис. 1.39 найдите мощность, потребляемую от каждого источника питания V₁ и V₂. Ваш входной файл на PSpice должен включать команды для вывода тока через каждый источник. Проверьте результат, найдя мощность, выделяемую во всех резисторах. Мощность для каждого резистора определите из выражений I²R и V²/R.Рис. 1.39

1.3. Для схемы на рис. 1.40 найдите V_ab (напряжение Тевенина) и R_ab (сопротивление Тевенина). В вашем входном файле должен быть отражен метод, предложенный в данной книге для определения этих значений.

Рис. 1.40

1.4. Для лестничной схемы на рис. 1.41 найдите входное сопротивление R_IN (сопротивление со стороны источника питания). Включите во входной файл команды, которые позволяют непосредственно вывести входное сопротивление.

Рис. 1.41

1.5. Для схемы на рис. 1.42 найдите напряжение V₁₂. Оно может быть определено просто как V(1)–V(2). Проверьте результат, включив во входной файл команды для непосредственного определения тока через R₂.

Рис. 1.42

1.6. Для схемы на рис. 1.43 найдите ток через резистор в 6 Ом и напряжение v.

Рис. 1.43

1.7. Для схемы на рис. 1.44 найдите напряжение v₂₃ и ток i.

Рис. 1.44

1.8. Для схемы на рис. 1.45 найдите напряжение на резисторе R₄.

Рис. 1.45

1.9. Для схемы на рис. 1.46 найдите напряжение n_аb.

Рис. 1.46

1.10. Для схемы на рис. 1.47 найдите напряжение v_ab и сопротивление R_ab, соответствующие теореме Тевенина.

Рис. 1.47

1.11. Для схемы на рис. 1.48 найдите эквивалентную схему Тевенина относительно полюсов а и b.

Рис. 1.48

Примечания:

4

В отечественной литературе этот метод называется методом суперпозиции, или наложения. (Прим. переводчика.)