• Главная
• В избранное
• Наш E-MAIL
• Добавить материал
• Нашёл ошибку
• Вниз

В предыдущих главах мы создавали собственные линейные модели для переменных составляющих, входящие в традиционный набор, который обычно используется в классическом анализе. Такой подход дает простые и ясные результаты, поэтому его следует использовать всегда, когда только возможно.

Однако часто возникает необходимость в более сложных моделях, учитывающих характеристики конкретных приборов. Набор таких моделей для приборов различных типов предоставляет пользователю программа PSpice, что делает ее мощным исследовательским инструментом.

Чтобы познакомить вас с концепцией использования встроенных моделей приборов, рассмотрим показанную на рис. 9.1 схему однополупериодного выпрямителя, состоящего из источника переменного напряжения, диода и резистора. Проблема здесь состоит в выборе модели диода. Мы могли бы моделировать диод как замкнутый ключ для положительных полупериодов входного напряжения и как разомкнутый ключ для отрицательных полупериодов. Если бы мы это сделали, то разделили бы проблему на две части, потому что в зависимости от режима должны были бы использовать два варианта модели. Однако нет никакой необходимости в таком подходе, поскольку PSpice имеет встроенную модель диода. Чтобы использовать ее, мы должны включить в наш входной файл команду .MODEL, которая имеет следующую форму:

MODEL <имя модели> <тип модели>

Рис. 9.1. Однополупериодный выпрямитель, использующий встроенную модель диода

Выберем для нашего примера D1 в качестве имени модели и D в качестве ее типа. Это необходимо, чтобы программа PSpice могла распознать устройство как диод встроенного типа. Проанализировать работу схемы можно с помощью следующего входного файла:

Half-Wave Rectifier Using Built-in Model

v1 1 0 sin(0 12V 1000Hz)

DA 1 2 D1

R 2 0 1k

.MODEL D1 D

.TRAN 0.1ms 1ms

.PROBE

.END

Обратите внимание на форму команды ввода диода:

DA 1 2 D1

Обозначение DA это выбранное нами имя диода. Оно всегда должно начинаться с D. Диод подключен к узлам 1 (анод) и 2 (катод). Запись D1 в конце строки задает имя модели диода.

Команда анализа переходных процессов .TRAN предусматривает вывод полного периода входного синусоидального напряжения и выходного напряжения на резисторе при частоте f=1 кГц.

Проведите анализ и получите в Probe график v(1) и v(2) для полного периода t=1мс. Убедитесь, что входное напряжение является синусоидальным, а выходное выпрямлено, и поэтому отрицательный полупериод отсутствует. На положительном полупериоде выходное напряжение отличается от входного на величину, равную падению напряжения на диоде. Используйте режим курсора, чтобы определить падение напряжения на диоде при максимуме входного напряжения. Убедитесь, что это падение напряжения равно 0,72 В. На рис. 9.2 показаны временные диаграммы входного и выходного напряжений.

Рис. 9.2. Входное и выходное напряжения в схеме на рис. 9.1

Листинг команды .MODEL может включать в себя и другие параметры. Например, кремниевые (Si) и германиевые (Ge) диоды имеют различные прямые падения напряжения и различные токи насыщения. Чтобы настроить модель диода, вы можете задавать до 14 параметров. Полный список этих параметров дан в разделе D — Диод приложения D.

Чтобы увидеть характеристику для встроенной модели диода в PSpice, можно провести анализ с вариацией входного напряжения на постоянном токе (dc sweep). Схема показана на рис. 9.3. При этом мы будем получать выходное напряжение «точка за точкой», строя характеристику так же, как снимали бы ее в лаборатории. Входной файл будет выглядеть следующим образом:

Built-in Diode Model for PSpice

V 1 0 10V

R 1 2 100

D1 2 0 DMOD

.DC V -0.5V 10V 0.02V

.MODEL DMOD D

.PROBE

.END

Рис. 9.3. Схема для снятия ВАХ диода

В данном примере мы подключили между узлами 2 и 0 диод D1 с именем модели DMOD, что отражено в первом аргументе команды .MODEL.

При проведении анализа в Probe измените границы оси X так, чтобы можно было представить V(2) в диапазоне до 0,8 В и I(D1) в диапазоне до 50 мА. Это даст вам характеристику встроенного диода (рис. 9.4) без изменения ранее определенных параметров. Чтобы отразить специфику конкретного прибора, вы можете изменять модель диода. Например, высота потенциального барьера EG по умолчанию равна 1.1 эВ. Задав новое значение, равное 0,72 эВ, мы отразим в нашей модели параметр, характерный для германиевого (Ge) диода. Вы можете посмотреть, как изменилась характеристика прибора после изменения любого параметра, и после этого продолжить анализ схемы, пользуясь измененной моделью.

Рис. 9.4. BAX диода 

Сгладить выходное напряжение можно, включив конденсатор параллельно сопротивлению нагрузки, как показано на рис. 9.5. Чтобы не допустить существенного снижения выходного напряжения на интервале, когда диод не проводит, емкость конденсатора должна быть выбрана достаточно большой.

Рис. 9.5. Двухполупериодный выпрямитель с емкостным фильтром

Решим эту традиционную задачу при R_L=1 кОм и стандартной частоте промышленной или бытовой сети f=60 Гц. Емкость фильтрового конденсатора выберем равной С=25 мкФ. Входной файл:

Half-Wave Rectifier with Capacitor Filter

V 1 0 sin (0 12 60)

DA 1 2 D1

R 2 0 1k

N 2 0 25uF

.MODEL D1 D

.TRAN 0.1ms 33.33ms

.PROBE

.END

Проведите анализ и выберите диапазон времени от 0 до 25 мс. Получите графики v(1) и v(2). Обратите внимание, что выходное напряжение следует за входным так же, как в первом примере, только до момента, когда напряжения достигают максимума. Затем, поскольку конденсатор был заряжен до максимального напряжения, диод перестает проводить. При этом конденсатор разряжается по экспоненте до момента, когда входное напряжение станет достаточным, чтобы снова перевести диод в проводящее состояние. Подробно эти процессы отражены на рис. 9.6.

Рис. 9.6. Процессы в однополупериодном выпрямителе с идеальным диодом и емкостным фильтром

При расчете этой схемы обычно пренебрегают падением напряжения на диоде. Уравнение для максимального тока через диод при этом равно:

Убедитесь, что при заданных значениях параметров, оно дает I_m=113,7 мА.

Ток изменяется согласно уравнению i=I_msin(ωt+θ), где θ определен как

θ = arctan ωCR_L,

а угол выключения равен

ωt₁ = π – θ = 180° – θ,

где t₁ — момент выключения диода.

Использование этих уравнений позволяет получить θ = 83,94° и

ωt₁ = 96,06°.

Добавьте еще одну ось Y, получите график I(DA). Из графика на рис. 9.7 видно, что выключение происходит в момент t=4,56 мс при величине угла ωt₁=98,5°. Убедитесь, что включение происходит в момент t₂=18,27 мс при ωt₂=34,8°.

Рис. 9.7. Временные диаграммы напряжений в схеме на на рис. 9.5

Максимальное значение выходного напряжения просто равно максимальному значению входного за вычетом падения напряжения на диоде. Это дает максимальное значение v(2)=11,23 В. Размах пульсаций выходного напряжения V_r=11,3–6,49=4,81 В. На рис 9.7 эти результаты представлены в графической форме.

Теперь нетрудно наблюдать влияние емкости С на размах пульсаций выходного напряжения. Измените емкость до значения С=50 мкФ и выполните анализ снова. Получите графики v(1) и v(2). Убедитесь, что размах пульсаций уменьшается при этом до V_r=2,802 В.

Чтобы лучше использовать входное напряжение, применяют двухполупериодный выпрямитель, схема которого приведена на рис. 9.8. Напряжения v₁ и v₂ снимаются с обмотки трансформатора с заземленной средней точкой. Выходное напряжение v₀ подается на R. Входной файл для этой схемы:

Full-Wave Rectifier

v1 1 0 sin(0 12 60Hz)

v2 0 3 sin(0 12 60Hz)

R 2 0 1k

D1 1 2 DA

D2 3 2 DA

.MODEL DA D

.TRAN 0.1ms 2 5ms

.PROBE

.END

Рис. 9.8. Модель двухполупериодного выпрямителя для анализа в PSpice

Проведите анализ и получите в Probe графики для двух входных напряжений v(1), v(3) и для выходного напряжения v(2). Здесь мы видим двухполупериодное выпрямление, когда на протяжении всего периода один из диодов проводит ток. Эти графики показаны на рис. 9.9. Удалите графики напряжений и получите затем график выходного тока I(R). Убедитесь, что ток I(R) достигает на каждом полупериоде максимума (I(R)_max=11.28 мА). Согласуется ли это с вашим расчетным значением? График тока нагрузки приведен на рис. 9.10.

Рис. 9.9. Входное и выходное напряжения при двухполупериодном выпрямлении

Рис. 9.10. Ток нагрузки при двухполупериодном выпрямлении

Подключите конденсатор емкостью 25 мкФ параллельно сопротивлению нагрузки R, добавив команду 

С 2 0

во входной файл предыдущего примера.

После проведения анализа получите график выходного напряжения v(2) вместе с входными напряжениями v(1) и v(3). Получите графики, отражающие влияние емкости конденсатора на напряжение пульсаций. Воспользовавшись режимом курсора, убедитесь, что v(2)_max=11,28 В и v(2)_min=8,79 В, что создает размах пульсаций напряжения V_r=2,52 В. Эти графики показаны на рис. 9.11.

Рис. 9.11. Входное и выходное напряжения при двухполупериодном выпрямлении с емкостной фильтрацией

Ограничитель используется, чтобы передать на выход только часть входного напряжения произвольной формы. Когда диод включается, происходит отсечка: на выход независимо от входного сигнала подается сумма напряжений на источнике и прямосмещенном диоде. На рис. 9.12 показана одна из таких схем. Входной файл для нее:

Diode Clipping Circuit

vi 1 0 sin(0 12V 60Hz)

DA 2 3 D1

R 1 2 1k

VR 3 0 8V

.MODEL D1 D

.TRAN 0.1ms 25ms

.PROBE

.END

Рис. 9.12. Простейшая схема диодного ограничителя 

Проведите анализ и получите график входного напряжения v(1) и выходного напряжения v(2). Можете ли вы предсказать, каким будет уровень ограничения? Почему он не равен в точности 8 В? Эти графики показаны на рис. 9.13.

Рис. 9.13. Входное и выходное напряжения в схеме на рис. 9.12 

Чтобы преобразовать синусоидальное напряжение в прямоугольное, используется двусторонний ограничитель. Для этой цели может служить простое последовательное соединение двух противовключенных стабилитронов (рис. 9.14). Выбраны стабилитроны, с напряжением зенеровского пробоя 2,4 В, используется встроенная модель диода, которая может быть легко преобразована в модель стабилитрона введением параметра BV для напряжения пробоя, как показано в следующем входном файле:

Double-Ended Clipper Using Avalanche Diodes

vi 1 0 sin(0 24V 60Hz)

DA 3 2 D1

DB 3 0 D1

R 1 2 1k

.MODEL D1 D(BV=2,4V)

.TRAN 0.1ms 2 5ms

.PROBE

.END

Рис. 9.14. Двусторонний ограничитель на базе встречновключенных стабилитронов 

Проведите анализ, получите графики входного v(1) и выходного v(2) напряжений. Обратите внимание, что выходное напряжение отсекается с двух сторон из-за действия противовключенных стабилитронов. Почему отсечка происходит таким образом, что выходное напряжение изменяется между значениями ±2,4 В? Проверьте, что выходное напряжение достигает максимума в 3,628 В. Оставьте на графике только кривую v(2), чтобы сделать прямоугольную форму более очевидной. Эти графики приведены на рис. 9.15.

Рис. 9.15. Входное и выходное напряжение в схеме на рис. 9.14

Часто для этой схемы показывают передаточную характеристику (характеристику выход-вход). Вы можете увидеть эту кривую, выведя по оси X напряжение v(1) и получив затем график v(2). Этот график покажет выходное напряжение при полном колебании входного напряжения. Обратите внимание, что эта кривая немного выходит за диапазон графика. Это объясняется тем, что анализ переходных процессов проводится при синусоидальном входном напряжении. Этого можно избежать, используя вариацию по постоянному току (dc sweep). Измените входной файл следующим образом:

Double-Ended Clipper Using Avalanche Diodes

VI 1 0 24V

DA 3 2 D1

DB 3 0 D1

R 1 2 1k

.MODEL D1 D(BV=2.4V)

.DC VI -24 24 0.1

.PROBE

.END

Проведите анализ и получите более качественную характеристику передачи. Входное напряжение VI выводится по оси X. Получите график V(2) на оси Y. Характеристика показана на рис. 9.16.

Рис. 9.16. Передаточная характеристика схемы на рис. 9.14 

Мы рассмотрели теорему о максимальной мощности для схем постоянного и переменного тока. В обоих случаях устанавливалась нагрузка и затем проводился анализ. Если мы изменяли значение нагрузки во входном файле, то анализ приходилось выполнять снова. Существует, однако, способ изменения нагрузки в рамках одного анализа. Опишем его.

На схеме (рис. 9.17) показан источник постоянного напряжения в 12 В с внутренним сопротивлением R_i=5 Ом, подключенный к переменному нагрузочному резистору R_L. Чтобы реализовать переменный резистор R_L, необходимо использовать команду .MODEL для резистора. Она выглядит следующим образом:

.MODEL RL RES

Рис. 9.17. Схема для исследования максимальной мощности при изменении сопротивления нагрузки

где RL — выбранное имя модели и RES — тип вызываемой модели. Использование модели позволяет нам включить RL в качестве варьируемого параметра в команду .DC sweep, показав диапазон значений для сопротивления. Команда при этом выглядит следующим образом:

.DC RES RL(R) 0.1 10 0.1

Здесь RES — имя варьируемой переменной, запись RL(R) использует выбранное нами имя модели, a (R) имя прибора, которым в данном случае является резистор. Весь входной файл:

Maximum Power with Variable Load Resistor

V 1 0 12V

RI 1 2 5

RLOAD 2 0 RL 1

.MODEL RL RES

.DC RES RL (R) 0.1 10 0.1

.PROBE

.END

Обратите внимание на команду RLOAD. Последний заданный в ней параметр — масштабный множитель 1. Это необходимое значение, без которого анализ не будет работать. Целью введения этого параметра в команду является стремление учесть различные множители, например, когда имеется несколько резисторов, использующих одну модель.

Выполните анализ и получите график

I(RI)·V(2),

представляющий собой мощность, выделяемую в резисторе нагрузки. Убедитесь, что максимум приходится на значение R=5 Ом, подставив RLOAD=5 Ом. Используйте курсор, чтобы показать, что Р_max=7,2 Вт. Этот график показан на рис. 9.18.

Рис. 9.18. Зависимость мощности от сопротивления

В начальных главах мы не использовали при анализе транзисторных схем встроенную модель для плоскостного биполярного транзистора (BJT). Хотя одно из основных преимуществ PSpice заключается в широком диапазоне и многосторонности встроенных моделей, в то же время эти сложные модели могут напугать начинающего пользователя. Например, встроенная модель Q для биполярного транзистора содержит 40 параметров, которые могут быть определены пользователем. Если вы посмотрите раздел «Q — биполярный транзистор» в приложении D, то увидите, насколько всесторонними являются эти параметры.

Многие из них вам, вероятно, совершенно не знакомы и выходят за рамки нашего обсуждения.

Чтобы представить модель биполярного транзистора, мы используем схему смещения усилителя с ОЭ, представленную на рис. 9.19. Такую схему вы могли бы использовать, если бы вам пришлось исследовать выходные характеристики биполярного транзистора в лаборатории. Вы получили бы подобную характеристику, поддерживая постоянным входной ток I_В при изменении напряжения V_CE. Большинство студентов знакомо с этим экспериментом. Рассмотрим теперь этот эксперимент с точки зрения PSpice. Мы вызываем транзистор Q1 и используем имя модели BJT. При использовании этих обозначений необходимая команда примет вид:

Q1 3 2 0 BJT

Рис. 9.19. Схема для снятия выходных характеристик усилителя ОЭ на биполярном транзисторе

Узлы приводятся в последовательности коллектор, база, эмиттер. Команда ввода модели:

.MODEL BJT NPN

где запись BJT выбрана в соответствии с нашим обозначением Q1, a NPN — тип модели для npn-транзистора. Получится следующий входной файл:

BJT PSpice Model Characteristics

VBB 1 0 1V

RS 1 2 10k

RL 3 4 0.01

Q1 3 2 0 BJT; 3=collector, 2=base, 1=emitter

VCE 4 0 5V

.MODEL BJT NPN

.DC VCE 0 15V 0.1V

.PROBE

.END

Проведите анализ и получите график -I(RL). Знак минус правилен относительно команды ввода R_L, показанной в файле. Используйте режим курсора, чтобы найти IC_max. Вы должны получить IC_max=2,07 мА. Характеристика показана на рис. 9.20. Удалите эту кривую и получите график I(RS), чтобы посмотреть входной ток I_B. Проверьте, что его максимальное значение I_В=20,7 мкА. Из двух полученных значений можно вычислить h_FE=100, что соответствует параметру B_F, приведенному в модели. При необходимости вы можете задавать другие значения для BF в некоторых моделях транзистора (см. список всех параметров транзистора в разделе «Q — биполярный транзистор» приложения D).

Рис. 9.20. Выходная характеристика для схемы на рис. 9.19

Входные характеристики могут быть получены из входного файла, который ссылается на встроенную модель следующим образом:

BJT Input Characteristics

IBB 0 1 100uA

Rs 1 0 1000k

RL 2 3 1k

Q1 2 1 0 BJT

VCC 3 0 12V

.MODEL BJT NPN

.DC IBB 0 100uA 1uA

.PROBE

.END

Из рис. 9.21 видно, что для этой модели npn-транзистора значение V_BE в активной области составляет около 0,8 В. Поскольку оно приблизительно на 0,1 В выше, чем то же значение в применявшейся нами ранее собственной модели для BJT, стандартная модель даст результаты, которые несколько отличаются от полученных ранее.

Рис. 9.21. Входная характеристика для схемы на рис. 9.19

Приложения А, В и D содержат распечатки моделей для других активных устройств, включая «В— GaAsFET» и «М — MOSFET». С точки зрения обучения вам полезнее использовать собственные модели для транзисторов и других устройств. Это позволит вам решать, какая из моделей более всего соответствует ситуации. Применение встроенных моделей в более сложных случаях позволит вам устанавливать параметры, которые в простых моделях не могут учитываться.

Дифференциальный усилитель используется в качестве первого каскада ОУ. В простейшем случае он напоминает схему на рис. 9.22. Для анализа мы используем встроенную модель для npn-транзистора, применив согласованную пару для Q1 и Q2, выбрав R_s1=R_s2=1 кОм и R_c1=R_c2=2 кОм.

Рис. 9.22. Дифференциальный усилитель (режим с дифференциальными входами)

Коэффициент усиления при работе в режиме дифференциального входа найдем, установив V_s1=–V_s2=V_s/2. Коэффициент усиления аппроксимируется выражением:

Для анализа выберем V_s=1 мВ, задав V_s1=0,5 мВ и f=1 кГц. Воспользовавшись встроенной моделью, вычислите ожидаемое значение A_d. Чтобы предсказать результаты, примите h_fe=100 и h_ie=2 кОм. Анализ должен дать значение A_d=33,3. Чтобы получить в выходном файле переменные составляющие, используйте команду .PRINT, как показано во входном файле:

Model for Differential Amplifier VS1 1 0 AC 0.5raV; Vs1 = -Vs2 = Vs/2

VS2 0 8 AC 0.5mV; This gives difference-mode operation

RSI 2 1 1k

RS2 7 8 1k

RE 3 9 5k

RC1 4 5 2k

RC2 5 6 2k

VCC 5 0 12V

VEE 0 9 6V

Q1 4 2 3 BJT

Q2 6 7 3 BJT

.AC LIN 1 1000Hz 1000Hz

.MODEL BJT NPN

.OPT nopage

.PRINT ACV(1) V(2) V(3) V(4) V(5) V(6) V(7) V(8)

.TF V(4) VS1

.END

Проведите анализ и получите распечатку выходного файла. Если вы удалите ненужную информацию, вы уменьшите этот файл до одной страницы объемом менее 60 строк. Проверьте, что A_d=V₀|V_s1=V(4)/V(1)=33,4. Обратите внимание на порядок следования узлов при описании входных напряжений V_s1 и V_s2 во входном файле. Кроме того, обратите внимание на то, что в выходном файле под заголовком «SMALL-SIGNAL CHARACTERISTICS» приведено отношение для соответствующих напряжений смещения. Нас же в большей степени интересует отношение переменных составляющих, приведенных в нижней части выходного файла на рис. 9.23.

Model for Differential Amplifier

**** CIRCUIT DESCRIPTION

VS1 1 0 AC 0.5mV ; Vs1 = -Vs2 = Vs/2

VS2 0 8 AC 0.5mV ; This gives difference-mode operation

RS1 2 1 1k

RS2 7 8 1k

RE 3 9 5k

RC1 4 5 2k

RC2 5 6 2k

VCC 5 0 12V

VEE 0 9 6V

Q1 4 2 3 BJT

Q2 6 7 3 BJT

.AC LIN 1 1000Hz 100GHz

.MODEL BJT NPN

.OPT nopage

.PRINT AC V(1) V(2) V(3) V(4) V(5) V(6) V(7) V(8)

.TF V(4) VS1

.END

**** BJT MODEL PARAMETERS

   BJT

   NPN

IS 100.000000E-18

BF 100

NF 1

BR 1

NR 1

CN 2.42

D  .87

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 0.0000  ( 2) -.0052  ( 3) -.7624  ( 4) 10.9630

( 5) 12.0000 ( 6) 10.9630 ( 7) -.0052  ( 8) 0.0000

( 9) -6.0000

VOLTAGE SOURCE CURRENTS

NAME CURRENT

VS1 -5.186E-06

VS2  5.186E-06

VCC -1.037E-03

VEE -1.048E-03

TOTAL POWER DISSIPATION 1.87E-02 WATTS

**** SMALL-SIGNAL CHARACTERISTICS

V(4)/VS1 = -1.680E+01

INPUT RESISTANCE AT VS1 = 1.191E+04

OUTPUT RESISTANCE AT V(4) = 2.000E+03

FREQ      V(1)      V(2)      V(3)      V(4)      V(5)

1.000E+03 5.000E-04 4.165E-04 6.371E-20 1.670E-02 1.000E-30

FREQ      V(6)      V(1)      V(8)

1.000E+03 1.670E-02 4.165E-04 5.000E-04

Рис. 9.23. Выходной файл для режима с дифференциальными входами

При работе в режиме с общим входом (ОВ) необходимо установить V_s1=V_s2= V_s. Коэффициент усиления в этом режиме можно аппроксимировать выражением:

Воспользовавшись известными значениями параметров транзистора, предскажите, каков будет этот коэффициент усиления. Измените входной файл так, чтобы входные напряжения выражались как

VS1 1 0 AC 1mV; Vs1 = Vs2

VS2 8 0 AC 1mV; Это режим работы с общим входом

После этих изменений снова выполните анализ и получите такую же распечатку выходного файла, как и прежде. Убедитесь, что Ас=V(4)/V(1)=0,197. Этот выходной файл показан на рис. 9.24.

Model for Differential Amplifier — Common Mode

**** CIRCUIT DESCRIPTION

VS1 1 0 AC 1mV ; Vs1 = Vs2

VS2 8 0 AC 1mV ; This gives common-mode operation

RS1 2 1 1k

RS2 7 8 1k

RE 3 9 5k

RC1 4 5 2k

RC2 5 6 2k

VCC 5 0 12V

VEE 0 9 6V

Q1 4 2 3 BJT

Q2 6 7 3 BJT

.AC LIN 1 1000Hz 1000Hz

.MODEL BJT NPN

.OPT nopage

.PRINT AC V(1) V(2) V(3) V(4) V(5) V(6) V(7) V(8)

.TF V(4) VS1

.END

**** BJT MODEL PARAMETERS

   BJT

   NPN

IS 100.000000E-18

BF 100

NF 1

BR 1

NR 1

CN 2.42

D  .87

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 0.0000  ( 2) -.0052  ( 3) -.7624  ( 4) 10.9630

( 5) 12.0000 ( 6) 10.9630 ( 1) -.0052  ( 8) 0.0000

( 9) -6.0000

VOLTAGE SOURCE CURRENTS

NAME CURRENT

VS1 -5.186E-06

VS2 -5.186Е-06

VCC -1.037E-03

VEE -1.048E-03

TOTAL POWER DISSIPATION 1.87E-02 WATTS

**** SMALL-SIGNAL CHARACTERISTICS

V(4)/VS1 = -1.680E+01

INPUT RESISTANCE AT VS1 = 1.191E+04

OUTPUT RESISTANCE AT V(4) = 2.000E+03

Рис. 9.24. Выходной файл для режима с общим входом

Важным аспектом при работе с дифференциальным усилителем является исследование его передаточной характеристики. Использование встроенной модели для транзистора облегчает эту задачу. Поскольку нас интересует режим малых сигналов при дифференциальном входном напряжении, используем вариацию параметров (dc sweep) для входных напряжений в диапазоне от -0,5 В до 0,5 В. Зафиксируем V_s2 на уровне 1 мВ; а варьировать будем параметр V_s1. При этом входной файл примет вид:

Transfer Characteristics of Differential Amplifier

VS1 1 0 1mV; это входное напряжение варьирует от -0.5 В до 0.5 В

VS2 8 0 1mV ; это напряжение остается фиксированным

RS1 2 1 1k

RS2 7 8 1k

RE 3 9 5k

RC1 4 5 2k

RC2 5 6 2k

VCC 5 0 12V

VEE 0 9 6V

Q1 4 2 3 BJT

Q2 6 7 3 BJT

.MODEL BJT NPN

.OP

.DC VS1 -0.5 0.5 0.01

.PROBE

.END

Выполните анализ и получите в Probe график -I(RC1). Сравните результаты с полученными ранее в этом разделе характеристиками передачи. Обратите внимание, что передаточная характеристика линейна не во всем диапазоне. Можете вы аппроксимировать линейный участок для V_s1 и I_RC1? Величины по оси X обычно нормализуются по температурному потенциалу V_T и задаются как

Вспомним, что при комнатной температуре V_T=26 мВ, и поэтому линейная часть кривой ограничена диапазоном 26 мВ. Характеристика передачи приведена на рис. 9.25.

Рис. 9.25. Нормализованная переходная характеристика схемы на рис. 9.22

Дифференциальный усилитель является хорошим ограничителем, и если входное напряжение при комнатной температуре превышает 100 мВ, усилитель переходит в режим насыщения. Проверьте команды входного файла по вашей распечатке для передаточной кривой. Можете ли вы получить зеркальное отображение этой кривой? Оно может быть получено, если сохранять фиксированным V_s1 при вариации V_s2. 

Рабочая версия PSpice содержит более сотни логических устройств, доступных в коммерческой версии программного обеспечения. Имеется большинство логических схем серии 7400, триггеры, счетчики и т.п. Полная распечатка логических устройств демонстрационной версии PSpice приведена в приложении Е.

Микросхема, содержащая единственную логическую схему ИЛИ-НЕ, показана на рис. 9.26. Напряжения на двух входах А и В показаны как последовательности импульсов различной длительности с амплитудой 1 В. Схема ИЛИ-НЕ вводится с помощью вызова подпрограммы (командой X) в которой узлы 1, 2 и 3 относятся ко входам А и В и выходу Y соответственно. При вызове подпрограммы устройство называется 7402. Окончательный вид входного файла:

Digital Circuit Using NOR gate

VCC 4 0 5V

X 1 2 3 7402

V1 1 0 PWL(Сs 0V 0.1ms 1V 1s 1V 1.0001s 0V

+2s 0V 2.0001s 1V 3s 1V 3.0001s 0V 4s 0V 4.0001s 1V 5s

+1V)

V2 2 С PWL(0s 0V 1.5s 0V 1,50001s 1V 2.5s 1V 2.50001s 0V

+3.5s 0V 3.50001s 1V 3.7s 1V 3.70001s 0V 5s 0V)

R 4 3 100k

.lib eval.lib

.tran 0.01ms 5s

.probe

.end

Рис. 9.26. Схема ИЛИ-НЕ с двумя входами

В приложении Е можно найти описание модели

.subckt 7402 А В Y …

в котором показана вся подпрограмма. Ее не нужно включать во входной файл, достаточно ссылки на библиотеку EVAL.LIB, которая содержит всю необходимую информацию. В Probe получите напряжения v(1) и v(2), отображающие входные сигналы A и B, и напряжение v(3), отображающее выходной сигнал Y. Ваши результаты должны соответствовать приведенным на рис. 9.27, который показывает сигналы в виде трех отдельных графиков. В совокупности они просто представляют собой диаграмму синхронизации для нашей логической схемы.

Рис. 9.27. Входное и выходное напряжения в схеме ИЛИ-НЕ 

В распечатке выходного файла (рис. 9.28) показана только часть общего файла. Распечатка параметров модели была опущена, чтобы сэкономить место. Обратите внимание, что аналого-цифровые команды реализуются в форме вызова подпрограмм, автоматически генерируемых подпрограммой 7402. Они имеются для каждого из трех узлов ИЛИ-НЕ. Команды для источника питания цифровой схемы также генерируются автоматически. Обратите внимание на листинг $G_DPWR=5 V наряду с другими узловыми напряжениями.

Digital Circuit Using NOR gate

VCC 4 0 5 V X 1 2 3 7402

V1 1 0 PWL(0s 0V 0.1ms 1V 1s 1V 1.0001s 0V

+2s 0V 2.0001s 1V 3s 1V 3,0001s 0V 4s 0V 4.0001s 1V 5s 1V)

V2 2 0 PWL (0s 0V 1.5s 0V 1.50001s 1V 2.5s 1V 2.50001s 0V

+3.5s 0V 3,50001s 1V 3.7s 1V 3.70001s 0V 5s 0V)

R 4 3 100k

.opt nopage

.lib eval.lib

.trail 0.01ms 5s

.probe

.end

**** Generated AtoD and DtoA Interfaces ****

* Analog/Digital interface for node 3

* Moving X.U1:OUT1 from analog node 3 to new digital node 3$DtoA

X$3_DtoA1

+ 3$DtoA

+ 3

+ $G DPWR

+ $G_DGND

+ DtoA_STD

+ PARAMS: DRVH= 96.4 DRVL= 104 CAPACITANCE= 0

*

* Analog/Digital interface for node 1

* Moving X.U1:IN1 from analog node 1 to new digital node 1$AtoD

X$1_AtoD1

+ 1

+ 1$AtoD

+ $G_DPWR

+ $G_DGND

+ AtoD_STD

+ PARAMS: CAPACITANCE= 0

* * Analog/Digital interface for node 2

* Moving X.U1:IN2 from analog node 2 to new digital node 2$AtoD

X$2_AtoD1

+ 2

+ 2$AtoD

+ $G_DPWR

+ $G_DGND

+ AtoD_STD

+  PARAMS: CAPACITANCE= 0

* Analog/Digital interface power supply subcircuits X$DIGIFPWR 0 DIGIFPWR

**** Diode MODEL PARAMETERS

**** BJT MODEL PARAMETERS

**** Digital Input MODEL PARAMETERS

**** Digital Output MODEL PARAMETERS

**** Digital Gate MODEL PARAMETERS

**** Digital IO MODEL PARAMETERS

**** INITIAL TRANSIENT SOLUTION TEMPERATURE = 27.000 DEG С

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 0.0000  ( 2) 0.0000  ( 3) 3.5028  ( 4) 5.0000

($G_DGND)    0.0000 ($G_DPWR)    5.0000

(X$1_AtoD1.1) .0915 (X$1_AtoD1.2) .0457

(X$1_AtoD1.3) .8277 (X$2_AtoD1.1) .0915

(X$2_AtoD1.2) .0457 (X$2_AtoD1.3) .8277

DGTL NODE : STATE DGTL NODE : STATE DGTL NODE : STATE DGTL NODE : STATE

( 2$AtoD) : 0     ( 3$DtoA) : 1     ( 1$AtoD) : 0

Рис. 9.28. Выходной файл при анализе схемы ИЛИ-НЕ

В качестве упражнения измените сигналы синхронизации для двух входов так, чтобы они создали области совпадения, отличные от уже использованных, и выполните моделирование снова. Опираясь на ваши теоретические сведения о работе схемы ИЛИ-НЕ, проверьте результаты.

В заключение замените схему 7402 на логическую схему И 7408 и проведите аналогичный анализ.

D[имя] <+узел> <-узел> <имя модели> [область]

Например, запись

DA 1 2 D1

показывает, что некоторый диод DA включен в схему между узлами 1 (анод) и 2 (катод). Модель для диода должна быть описана в команде .MODEL, которая носит имя D1. В схеме может быть несколько диодов, например DA, DB и DC, использующих одну и ту же модель.

J[имя] <узел стока> <узел затвора> <узел истока> <имя модели> [область]

Например, запись

J 5 4 2 JFET

показывает, что некоторый полевой транзистор (JFET) подключен к узлам 5 (сток), 4 (затвор) и 2 (исток). Модель для полевого транзистора должна быть описана в команде .MODEL с именем JFET. Схема может содержать несколько полевых транзисторов, например J, J1 и J2, использующих одну и ту же модель.

Q[имя] <узел коллектора> <узел базы> <узел эмиттера> [узел подложки] <имя модели> [область]

Например, запись

Q1 3 2 0 BJT

показывает, что некоторый биполярный транзистор Q₁ подключен к узлам 3 (коллектор), 2 (база) и 0 (эмиттер). Модель для биполярного транзистора должна быть описана в команде .MODEL, которая носит имя BJT. Схема может содержать несколько транзисторов, например Q₁, Q₂ и Q₃, использующих одну и ту же модель.

R[имя] <+узел> <-узел> <имя модели> [значение]

Например, запись

RLOAD 2 0 RL 1

показывает, что резистор RLOAD включен между узлами 2 и 0. Модель резистора носит имя RL и описывается командой .MODEL. Последняя запись (1 после RL) представляет собой масштабный множитель, равный единице. Значение масштабного множителя может быть и другим. Масштабный множитель 2 показывал бы, что значение, заданное в модели, удваивается. Одной из причин, по которым для описания резисторов используются модели, является возможность применения команды .DC, при которой сопротивление RES выбирается в качестве переменной при вариации параметров. Дополнительную информацию дают команды с точкой.

.MODEL <имя модели> <тип>

Например, запись

.MODEL D1 D

используется, чтобы определить модель диода. Запись D показывает, что применяется модель прибора из библиотеки PSpice. Библиотека содержит модели следующих типов приборов:

САР (конденсатор);

IND (катушка индуктивности);

RES (резистор);

D (диод);

NPN (биполярный транзистор типа npn);

PNP (биполярный транзистор типа pnp);

NFJ (n-канальный полевой транзистор);

PFJ (р-канальный полевой транзистор);

NMOS (n-канальный MOSFET);

PMOS (р-канальный MOSFET);

GASFET (n-канальный GaAs MOSFET);

ISWITCH (ключ, управляемый током);

VSWITCH (ключ, управляемый напряжением);

CORE (нелинейный трансформатор с магнитным сердечником).

Более полная форма для команды, описывающей модель:

.MODEL <имя модели> <тип> [(<имя параметра> = <значение>)]*

Например, запись

.MODEL D1 D (IS = 1E-12 N=1.2 VJ=0.9 BV=10)

показывает, что один из 14 параметров диода имеет значение, отличающееся от заданного по умолчанию. Звездочка после скобок означает, что заключенные в них пункты могут повторяться. В приложении D приведен список всех библиотечных приборов, различных параметров их моделей и значения параметров, заданные по умолчанию.

9.1. Однополупериодный выпрямитель, показанный на рис. 9.1, имеет следующие параметры: IS=1Е-9 A, VJ=0,8 В, IBV=1Е-6А и EG=0,72 эВ. Выполните анализ, аналогичный описанному в тексте, и сравните результаты с полученными ранее. Какие различия в результатах можно увидеть?

9.2. Диодная схема, содержащая последовательно включенные источники постоянного и переменного напряжений, показана на рис. 9.29.

Рис. 9.29

Используйте при анализе встроенную модель диода. Задайте значения V=0,8 В и R=1 кОм. Переменное напряжение задано синусоидальной функцией с амплитудой 0,2 В и частотой f=1 кГц.

а) Проведите анализ и получите в Probe графики напряжений v(2,1) и v(3). Проводит ли диод в течение всего периода? Проверьте и объясните результаты.

б) Проведите анализ при V=0,6 В. Объясните результаты.

в) Проведите анализ при V=0,4 В. Объясните результаты.

9.3. На рис. 9.4 приведена ВАХ для встроенной модели диода. Получите характеристику для диода, параметры которого приведены в задаче 9.1. Опишите все различия в двух кривых.

9.4. Двухполупериодный выпрямитель с емкостным фильтром, использующим конденсатор с емкостью С=25 мкФ, рассмотрен в тексте. Используйте аналогичный анализ, чтобы определить размах пульсаций и среднее значение выходного напряжения при С = 10 мкФ.

9.5. Схема, показанная на рис. 9.30, подобна схеме на рис. 9.12, за исключением того, что диод включен в обратном направлении. Проведите анализ при максимальном напряжении v_i=12 В, частоте f=60 Гц и V_R=8 В и получите входное и выходное напряжения. Попробуйте предсказать форму выходного напряжения и сравните предсказанные результаты с полученными в Probe.

Рис. 9.30

9.6. В схеме, приведенной на рис. 9.31, используются те же параметры, что и в задаче 9.5. Выходное напряжение снимается с последовательного соединения R и V_R. Предскажите форму выходного напряжения, затем выполните анализ на PSpice и сравните результаты.

Рис. 9.31

9.7. Для схемы на рис. 9.32, содержащей встроенную модель биполярного транзистора, найдите напряжения и токи покоя. Установите h_FE=80 (BF=80 в команде .MODEL). Обратите внимание, что схема подобна схеме на рис. 3.1. Сравните результаты, полученные здесь, с приведенными в главе 3. Обратите внимание, что имеются существенные различия в результатах. Напряжение VA (рис. 3.2) составляет 0,7 В, что отражает типичное для реальных транзисторов значение напряжения V_BE в активной области. При использовании встроенной модели выходной файл должен показать V_BE=0,806 В. Эти различия вызывают изменения в токе базы и других величинах, полученных в обоих случаях. Эта задача показывает одну из причин, по которым собственные модели (подобные рассмотренным в главе 3) часто предпочитают встроенным моделям.

Рис. 9.32

9.8. В схеме, показанной на рис. 9.33, получите стоковые характеристики полевого транзистора. Задайте изменение напряжения сток-исток V_DS от 0 до 18 В с шагом в 0,2 В. Используйте встроенную модель для плоскостного полевого транзистора (JFET) с обозначением NJF (полевой транзистор с n-канальным переходом).

а) Используйте напряжение затвор-исток V_GS=0 В. Найдите максимальный ток стока и напряжение отсечки.

б) Установите значение V_GS=-1 В и снова проведите анализ.

Рис. 9.33

9.9. На рис. 3.7 показана схема усилителя с общим эмиттером на биполярном транзисторе, использующая модель в h-параметрах. Если h-параметры не используются и для анализа выбирается встроенная модель, то на схеме должен быть показан источник питания V_cc и цепи базового смещения. Полная схема может быть, например, такой, как на рис. 9.34. Используйте встроенную модель для биполярных транзисторов (BJT), установив h_FF=50 (BF=50) и создав входной файл для определения коэффициента усиления по напряжению для низких частот. Анализ проведите на частоте 5 кГц. Сравните результаты с полученными при использовании модели в h-параметрах. Какой из методов предпочтителен для задач этого типа? Почему?

Рис. 9.34.